Perl从数组中获取最小的数字[关闭]

Question

你好，我想在这里获得最低的成本是我的 json

[
'ups_standard_international|23.63',
'ups_worldwide_saver|20.8',
'ups_worldwide_express|21.11',
'ups_worldwide_expedited|18.75',
'usps_first_class_package_international|33.43',
'usps_priority_mail_international|42.34',
'usps_priority_mail_express_international|61.79'
];

我希望它显示 ups_worldwide_expedited|18.75

因为这是最低的成本。

谢谢。

Answer 1

这里是您在 Perl 中执行此操作所需的信息。它实际上是 1 到 3 行代码。如果之后您有特定的 Perl 问题，请提出一个新问题。

假设您有一个 JSON 文件或文本 sn-p，请使用 JSON 模块对其进行解析。 https://metacpan.org/pod/JSON

在 Perl 中将其放入数组后，使用 foreach 遍历每个元素，并使用 split 或正则表达式解析成本字段。

如果成本小于当前成本，则只需将行和成本分配给变量。预先将成本变量初始化为不可能大的值，例如 1E9。循环结束后，打印出 line 变量。

这里是 Perl 文档的链接。
https://perldoc.perl.org/perl#Tutorials

你会发现 perlfunc 和 perlop 特别有用。

Answer 2

您可以使用哈希来跟踪迭代值时看到的最低成本

#!/usr/bin/perl

use strict;
use warnings;

my $aref = [
    'ups_standard_international|23.63',
    'ups_worldwide_saver|20.8',
    'ups_worldwide_express|21.11',
    'ups_worldwide_expedited|18.75',
    'usps_first_class_package_international|33.43',
    'usps_priority_mail_international|42.34',
    'usps_priority_mail_express_international|61.79'
];

my %lowest;

foreach (@$aref) {
    my ( undef, $cost ) = split /[|]/;
    if ( !%lowest || $cost < $lowest{cost} ) {
        $lowest{cost} = $cost;
        $lowest{line} = $_;
    }
}

print $lowest{line}, "\n";

编辑：我可能误解了 OP 的问题。 如果问题中“json”的sn-p不是Perl对象，而是一个原始的JSON字符串，我们可以使用JSON模块来做​​基本相同的事情，这里是上面代码的更新版本：

#!/usr/bin/perl

use strict;
use warnings;

use JSON qw(decode_json);

my $json = <<'END_JSON';
[
    'ups_standard_international|23.63',
    'ups_worldwide_saver|20.8',
    'ups_worldwide_express|21.11',
    'ups_worldwide_expedited|18.75',
    'usps_first_class_package_international|33.43',
    'usps_priority_mail_international|42.34',
    'usps_priority_mail_express_international|61.79'
]
END_JSON

# First, use double quotes to quote the strings above, to make it valid JSON:
$json =~ s/^(\s*)'([^']+)'(,?)\s*$/$1"$2"$3/gms;

# Now decode the JSON above into a perl array
my @array = @{ decode_json($json) };

# This hash will hold the element with the lowest cost
my %lowest;

# While the array still has elements, take one line from it
while ( my $line = shift @array ) {

    # Extract the cost from the line
    my ( undef, $cost ) = split /[|]/, $line, 2;

    # If this cost is the lowest we've seen yet, put it in the %lowest hash
    if ( !%lowest || $cost < $lowest{cost} ) {
        $lowest{cost} = $cost;
        $lowest{line} = $line;
    }
}

print $lowest{line}, "\n";