使用正则表达式搜索 Perl 数组并仅返回单个捕获组

Question

我有一个 Perl 脚本，我在其中循环执行 Web 服务调用。服务器返回一个多值 HTTP 标头，我需要在每次调用后对其进行解析，其中包含我需要进行下一次调用的信息（如果它不返回标头，我想退出循环）。

我只关心标题中的一个值，我需要使用正则表达式从中获取信息。假设header是这样的，我只关心“foo”的值：

X-Header: test-abc12345; blah=foo
X-Header: test-fgasjhgakg; blah=bar

我可以像这样得到标题值：@values = $response->header( 'X-Header' );。但是如何快速检查是否

1. 有一个 foo 值，并且
2. 解析并保存 foo 值以供下一次迭代使用？

理想情况下，我想做这样的事情：

my $value = 'default';

do {
  # (do HTTP request; use $value)
  @values = $response->header( 'X-Header' );
} while( $value = first { /(?:test-)([^;]+)(?:; blah=foo)/ } @values );

但grep、first（来自List::Util）等都返回整个匹配，而不仅仅是我想要的单个捕获组。我想通过循环遍历数组并在循环体内进行匹配/解析来避免弄乱我的代码。

我想要的可能吗？写它的最紧凑的方式是什么？到目前为止，我能想到的只是使用lookarounds 和\K 来丢弃我不关心的东西，但这不是超级可读的，并且会使正则表达式引擎执行很多不必要的步骤。

Answer 1

因此，您似乎想以某种模式捕获第一个元素，但只获取该模式。你希望它做得很好。事实上，first 和 grep 只传递元素本身。

不过，List::MoreUtils::first_result 确实支持处理其匹配项

use List::MoreUtils 0.406 qw(first_result);

my @w = qw(a bit c dIT);  # get first "it" case-insensitive

my $res = first_result { ( /(it)/i )[0] } @w;

say $res // 'undef';  #--> it

( ... )[0] 需要将正则表达式放在列表上下文中，以便它返回实际捕获。另一种方法是firstres { my ($r) = /(it)/i; $r }。选择你的选择

---

对于问题中的数据

use warnings;
use strict;
use feature 'say';

use List::MoreUtils 0.406 qw(firstres);

my @data = ( 
    'X-Header: test-abc12345; blah=foo',
    'X-Header: test-fgasjhgakg; blah=bar'
);

if (my $r = firstres { ( /test-([^;]+);\s+blah=foo/ )[0] } @data) {
    say $r
}

打印abc12345，在评论中澄清为寻求的结果。

---

0.406（2015-03-03）之前的模块版本没有firstres（别名first_result）

Answer 2

first { ... } @values 返回值之一（或undef）。

您可以使用以下任何一种：

my ($value) = map { /...(...).../ } @values;

my $value = ( map { /...(...).../ } @values ) ? $1 : undef;

my $value = ( map { /...(...).../ } @values )[0];

使用first，它看起来像下面这样，这是相当愚蠢的：

my $value = first { 1 } map { /...(...).../ } @values;

但是，假设捕获不能是空字符串或字符串0，则可以使用List::MoreUtils 的first_result 来避免不必要的匹配：

my $value = first_result { /...(...).../ ? $1 : undef } @values;

my $value = first_result { ( /...(...).../ )[0] } @values;

如果返回的值可以为假（例如空字符串或0），您可以使用类似

my $value = first_result { /...(...).../ ? \$1 : undef } @values;
$value = $$value if $value;

first_result 方法在实践中不一定更快。

Answer 3

以下代码 sn-p 正在寻找存储在变量$find 中的foo，找到的值存储在变量$found 中。

my $find = 'foo';
my $found;

while( $response->header( 'X-Header' ) ) {
    if( /X-Header: .*?blah=($find)/ ) {
        $found = $1;
        last;
    }
}

say $found if $found;

示例演示代码

use strict;
use warnings;
use feature 'say';

use Data::Dumper;

my $find = 'foo';
my $found;
my @header = <DATA>;

chomp(@header);

for ( @header ) {
    $found = $1 if /X-Header: .*?blah=($find)/;
    last if $found;
}

say Dumper(\@header);
say "Found: $found" if $found;

__DATA__
X-Header: test-abc12345; blah=foo
X-Header: test-fgasjhgakg; blah=bar

输出

$VAR1 = [
          'X-Header: test-abc12345; blah=foo',
          'X-Header: test-fgasjhgakg; blah=bar'
        ];

Found: foo