Perl：在不创建新变量的情况下测试正则表达式

Question

对不起，如果这是一个基本问题，但我对 perl 有点陌生，我觉得应该有办法做到这一点，但找不到任何文档。我想知道您是否可以在没有丢弃变量$doto 的情况下执行以下操作：

my $file="foo/bar.c";
my $doto = $file;
$doto =~ s/\.c$/\.o/;
print ".o exists" if ( -f $doto );

也就是说，类似于：

print ".o exists" if ( -f ($file =~ s/\.c$/\.o/gr) );

（但这当然会产生编译错误）。

我的编译错误如下：

在第 2 行，“s/.c$/.o/gr”附近的操作员预期的位置找到了裸字

这是perl, v5.8.9

Answer 1

你的陈述

print ".o exists" if ( -f ($file =~ s/\.c$/\.o/gr) )

在支持/r 修饰符的 Perl 版本（v5.14 或更高版本）上运行良好。 （注意/g是多余的。）

没有它，就无法在不修改变量的情况下应用替换，尽管您可以使用块使其成为非常短暂的临时变量

{
    (my $doto = $file) =~ s/\.c$/\.o/;
    print ".o exists" if -f $doto;
}

Answer 2

这个答案谈到使实际的print if -f 查找代码更具可读性。如果你想让代码运行得更快，这个方案比你的丑方案要贵。

由于在您的 Perl 版本中没有非破坏性替代，您所能做的就是为此实现您自己的函数。它不会像s///r 那样好，但它可以胜任。如果您多次出现这种类型的代码，那将是有意义的。

sub replace {
    my ($text, $pattern, $replacement) = @_;

    $text =~ s{$pattern}{$replacement}g; # do you need /g?
    return $text;
}

# ... later

print ".o exists" if -f replace($file, qr/\.c$/, '.o');

这已经为您制作了一份副本，就像您的临时变量一样，所以 $file 实际上不会被更改。

请注意，您的 /g 是无用的，因为文件名只会有一行的结尾，但以后可能不会没用。但是，最好不要在那里修复它，而是传入一个可选标志作为另一个参数。

replace( $file, qr/.../, '.o', 'g' ); # where 'g' just means any true value

sub replace {
    my ($text, $pattern, $replacement, $global) = @_;

    if ($global) {
         $text =~ s{$pattern}{$replacement}g;
    } else {
         $text =~ s{$pattern}{$replacement};
    }

    return $text;
}

您通常也不需要转义替换部分中的.，因为这实际上不是正则表达式模式，只是一个字符串。

Answer 3

我会通过添加如下函数来处理它。

sub doto_exists {
    my $doto = shift;
    $doto =~ s/\.c$/\.o/;
    return (-f $doto);
}

$file = "file1.c";

print ".o exists\n" if doto_exists($file) ;