perl 用户输入“动态/自动标签扩展”

Question

我有一个小命令行工具的想法，希望它能让我更快地浏览目录，我需要知道如果给定一个来自 的字符，是否有可能在 perl 中自动将字符注入 取决于上下文（所以如果情况正确，它看起来像是一个不请自来的标签扩展）。

例如，假设我在某处的某个目录中有以下目录：

dir1 directory_2 test testing tested experiments

测试中包含的是目录

fully_tested partially_tested 

然后调用脚本将首先列出我调用的所有目录 cd-able 并等待输入。如果我输入的第一个字符是“t”，我想自动将“est”注入 STDIN（因为“test”在 test、testing 和tested 的联合中），列出所有以“test”开头的目录并等待进一步输入。

如果下一个字符是 'e' 或 'i' 它会自动 cd 分别进入测试或测试（因为这些目录是唯一确定的），如果它是一些尚未确定的“容易到达的关键”，比如* 我会 cd 进入测试，点击 '.'会做一个 cd ..，并且点击任何其他字母字符都没有效果（也许其他一些容易到达的键可能会列出所有内容）。

回到示例，输入字符 'tef' 意味着我将 cd 进入 testing/fully_tested（因为 'te' 唯一匹配 testing 而 'f' 唯一匹配 fully_tested）

至于实际编码，我希望它是我自己的问题（我相信可以逐个字符地处理输入）所以重申一下，我在这里要问的是：

---

perl 是否提供了某种机制，通过该机制可以在没有用户交互的情况下修改 STDIN（这样我可以在命令行上模拟 tab-expand，但这种扩展发生在幕后）？或者换句话说，在评估最后一个输入时，我想静默地进行选项卡扩展（根据命令行，它对我的​​输入流“看起来像一个选项卡扩展”）而不显式点击

---

更多细节：据我所知，我目前正在做什么，一旦编码完成，在运行时会如下所示（假设我的主目录有文件夹桌面、文档、Documents_bak、下载、音乐）

Desktop/ Documents/ Documents_bak/ Downloads/ Music
D
Desktop/ Documents/ Documents_bak/ Downloads
o
Documents/ Documents_bak/ Downloads
c
Documents/ Documents_bak
_
programming/ books/ ...(other directories)

这看起来不太好......我真正想要的是类似的东西

Desktop/ Documents/ Documents_bak/ Downloads/ Music
D
Desktop/ Documents/ Documents_bak/ Downloads
Do
Documents/ Documents_bak/ Downloads
Documents
Documents/ Documents_bak
Documents_bak/
programming/ books/ ...(other directories)
Documents_bak/

最后一行“Documents_bak/”实际上是输入流，就好像我已经全部输入了一样（所以如果我愿意，我可以删除其中的一些）。只是如何实现这一点 这给我带来了问题

编辑* 我不是（据我所知）试图在这里重新发明轮子——我只是想在更改目录时删除 、、重新键入“cd”步骤。 IE。使用我的方案，只需“tef”即可 cd 进入测试/完全测试但在 bash 我需要“ticdf” 来做同样的事情.

Answer 1

Term::ReadKey 可能是您问题的答案。它不能保证在所有系统上都能正常工作，但它可以提供您要求的控制。

这是一个在我的 Ubuntu 机器上运行良好的示例。

#!/usr/bin/perl
use strict;
use Term::ReadKey;

#a simple sub to return directories in supplied path 
sub list_dirs {
    my $path = shift;
    my @dirs;
    opendir DIR, $path or die "can't opendir '$path' : $!";
    my @dirs = grep {-d $path.'/'.$_} grep {$_ !~ m/^\.+$/} readdir DIR;
    closedir DIR;
    return @dirs;
}
#my start directory
my $home = '/path/to/startdir'; 
#my current directory, this will change
my $curdir = $home; 
#fetch the first list
my @dirs = list_dirs($curdir);

#read chars without pressing Enter
ReadMode 'cbreak'; 

#since we only need a char at a time
#we should remember our previous input
my $input;
#this var holds the real user input (without the autocomplete)
my $realinput;
#all the processing happens here, in the while loop, char by char
while (my $key = ReadKey(0)) {
    #validate input by allowed chars.
    #special chars like backspace, tab and enter can be handled separately
    if (ord($key) == 127) { #backspace
        chop $realinput;
        $input = $realinput;
        $key = '';
    #other special char checks can be added here
    } elsif ($key =~ m/^[\w\d\.\/\-]$/) { #allowed chars (more should be added)
        $realinput = $realinput.$key;
    } else {
        print "\ninvalid input\n$input";
        next; #ignore this char and ask for another
    }

    my @found = grep {$_ =~ m/^$input$key/} @dirs;
    #if we added a trailing slash or pressed enter, 
    #then limit our search to find one dir that exactly matches
    @found = grep {$_ =~ m/^$input$/} @dirs if ($key eq '/' || ord($key)==10);

    if  (scalar(@found) == 0) {
        #not dir matching, do nothing
        print "\nNo match\n$input";
    } elsif (scalar(@found) == 1) {
        #only one dir found
        #cd and reset input
        $curdir .= '/'.$found[0];
        my @dirs = list_dirs($curdir);
        $input = '';
        $realinput = '';
        print "\ncd to $curdir\n";
    } elsif (scalar(@found) > 1){
        print "\n".join(' ',map {$_.'/'} @found);
        $input .= $key;
        #find least match of matching dirs and autocomplete as much as possible 
        #assign the smallest matching string to $input and go to next loop
        for (my $i = length($input); $i <= length($found[0]); $i++) {
            my $matchcount = 0;
            my $tmpstr = substr($found[0], 0, $i);
            foreach my $d(@found) {
                $matchcount++ if ($d =~ m/^$tmpstr/);
            }
            if ($matchcount == scalar(@found)) {
                $input = $tmpstr;
            } else {
                last;
            }
        }
        print "\n$input";
    }
}

编辑：

我已经更新了我的脚本。添加了自动完成支持，例如在 bash 中按 TAB 时，以及退格支持和检查某些字符。此外，我还添加了一个用于列出目录的斜杠，并再次检查是否完全匹配。因此，如果您有目录 Documents/ 和 Documents_bak/，在输入中按 D 将自动完成到 Documents，您必须按 / 或 Enter 到 cd 到 Documents/。

我认为这个脚本是展示一切皆有可能的好方法。然而，每个目标都需要一定的工作量。替换用 perl 脚本编译的几乎 1MB 的 bash 不是一个现实的目标。但是您要求的行为在此脚本中得到了准确的演示。可以通过更多检查、更多特殊键处理和更多代码清理/优化来丰富它。