Perl 删除节点答案

【问题标题】：Perl removing nodePerl 删除节点
【发布时间】：2019-11-13 02:04:49
【问题描述】：

我从 Perl 开始，我知道有一些类似的问题得到了解答，但是（由于我缺乏经验）它们都没有帮助。

我有这样的xml：

<workflowVertices>
    <workflowVertex>
    <alias />
    <task>Task_L2</task>
    <vertexId>128</vertexId>
</workflowVertex>
<workflowVertex>
     <alias />
     <task>preTask_L1</task>
         <vertexId>129</vertexId>
   </workflowVertex>
</workflowVertices>

我需要删除所有具有 node task =~ m/_L1/ 的 workflowVertex 节点

我现在拥有的：

my $dom = XML::LibXML->load_xml(location => $filename);

foreach my $name ($dom->findnodes('workflowVertices/workflowVertex/task')) 
{
#say $name->to_literal();
if ($name->to_literal() =~ m/_L1/) {
    say "JobName: " . $name->to_literal() . " to be deleted\n";
    my $node = $name->to_literal();
    my $parent = $name-> parentNode();
    say $parent-> removeChild("task[$node]")
    }
}

但是当我执行它时它会出错：

XML::LibXML::Node::removeChild() -- node is not a blessed SV reference at

xmltransform.pl 第 28 行。

第 28 行。在我的代码中是

say $parent-> removeChild("task[$node]")

有人可以帮我吗？

【问题讨论】：

投票结束，因为问题是由拼写错误引起的。该方法称为removeChild，而不是RemoveChild。
@JanFi86 也许这有帮助：ubuntuforums.org/showthread.php?t=299381
@JanFi86：所以有人修复了您发布的问题，您通过编辑问题来提出不同的问题来回应？这有点粗鲁，真的。请恢复您的编辑并在新帖子中提出您的新问题。
@Dave Cross，对不起，谢谢你的指教。我认为如果问题仍然存在于同一行代码中，那么最好留在同一个问题上。但我至少应该肯定会在那里发表编辑评论。下次我会更小心的，没有恶意。谢谢

标签： xml perl xml-libxml

【解决方案1】：

这里是documentation for the removeChild() method：

移除孩子
$childnode = $node->removeChild( $childnode );
这将解除子节点与其父节点$node 的绑定。函数返回未绑定的节点。如果oldNode 不是给定节点的子节点，则函数会失败。

（那里有一个错字 - 上面写着oldNode，我很确定它的意思是$childNode。）

也许不是很清楚，但你需要传递removeChild() 一个节点对象，而不仅仅是一个字符串。您将文字字符串“task[preTask_L1]”传递给它，我真的不确定您从哪里得到这个想法。

我认为你为你的变量使用了不好的名字而让自己很困惑。您的 $name 变量包含一个节点对象，而不是名称。您的 $node 变量包含来自节点的文本（可能被视为其“名称”）。

我认为最简单的解决方法是将您的代码行更改为：

say $parent->removeChild($name);

但我真的建议也修复这些变量名。你的维护程序员（很可能在六个月后成为你）会感谢你的 :-)

【讨论】：

谢谢@Dave Cross，现在它工作了。还有一个问题……如果我想删除的不仅仅是task节点而是workflowVertex，它是父节点怎么办？我的意思是根据子节点值删除父节点......你也帮我吗？
我想我找到了解决方案：my $parent = $name-> parentNode->parentNode; say $parent->removeChild($name->parentNode);

【解决方案2】：

首先，请使用更好的变量名。你可怕的名字（$name 是一个 task 节点，$node 根本不是一个节点，不清楚 $parent 指的是谁的父级，等等）使你的代码非常难以阅读。

你可以使用

$vertex_node->parent->removeChild($vertex_node);

或

$vertex_node->unbindNode;

删除节点。固定：

my $dom = XML::LibXML->load_xml( location => $filename );

for my $task_node ($dom->findnodes('/workflowVertices/workflowVertex/task')) {
    my $task_name = $task_node->textContent();
    if ($task_name =~ /_L1/) {
        my $vertex_node = $task_node->parent;
        $vertex_node->unbindNode;
        say "Deleted task $task_name.";
    }
}

替代方法：

my $dom = XML::LibXML->load_xml( location => $filename );

for my $vertex_node ($dom->findnodes('/workflowVertices/workflowVertex')) {
    my $task_name = $vertex_node->findvalue('task/text()');
    if ($task_name =~ /_L1/) {
        $vertex_node->unbindNode;
        say "Deleted task $task_name.";
    }
}

如果不需要打印任务名称，甚至可以缩成如下：

my $dom = XML::LibXML->load_xml( location => $filename );

$_->unbindNode
    for $dom->findnodes('/workflowVertices/workflowVertex[contains(task/text(), "_L1")]');

【讨论】：