如何在perl的哈希中将多个值相互比较？

Question

我有一个看起来像这样的哈希

my %hash = (key1 => [value1],
           key2 => [value1,value2],
           key3 => [value3,value3,value3],
           key4 => [value2,value2,value2]
           );

现在我想将这些值相互比较并挑选出奇数键。即所有值都不相同的键，在本例中为key2 取出每个键并迭代数组似乎是一种折磨。有没有简单的方法可以做到这一点？ 我想使用这个奇怪的键并打印出值/在哈希中给它一个计数 例如。

   my %hash2;
   $hash2{key2}{value1} =2;
   $hash2{key2}{value2} =2;

我该如何做到这一点？

Answer 1

为了找到您感兴趣的键，您可以过滤具有多个唯一元素的值。对于uniq，您可以使用List::MoreUtils，或者如果您想避免使用模块，您可以自己定义函数（explanation here）

sub uniq {
  my %seen;
  return grep { !$seen{$_}++ } @_;
}

然后您可以像这样过滤键：

# get an array of pairs of "uniq count" and "key"
my @key_counts = map {[uniq(@{$hash{$_}})+0, $_]} keys %hash;
# filter this array for those with "uniq count" greater than 1 and only keep key
my @keys_of_interest = map {$_->[1]} grep {$_->[0] > 1} @key_counts;
# if you know that there is only a single key of interest
my $key = $keys_of_interest[0];

您可以使用此$key 和对应的value 来获取您的%hash2：

my %hash2;
$hash2{$key}{$_} = 2 foreach(@{$hash{$key}});

Answer 2

use warnings;
use strict;

my @odd_keys;

my %hash = (key1 => [1],
            key2 => [1,2],
            key3 => [3,3,3],
            key4 => [2,2,2]
           );

foreach my $key (keys(%hash))
{
  #builds an array with every cell equal to first cell 
  my @temp_array = grep {$_ eq $hash{$key}->[0]} @{$hash{$key}};
  #if the size of this array is different than the size of array associated to key, that means that all values are not equal
  if (@temp_array != @{$hash{$key}})
  {
    print "$key\n"; 
    push(@odd_keys, $key);
  }
}

打印奇数键并创建一个@odd_keys 数组