perl中如何将字符串转换为哈希表

Question

我有一个来自 for 循环的字符串：

@file = "/path/window/*_testing_42.csv";


foreach $file(@file) {


$name = $file=~ /(\w*)_testing_42/; #comes from file path
$name = 1$;
print $name; #prints G43B76P90T45

}

我需要这个字符串中的 4 个值（G43、B76、P90、T45）。我想将它们放入散列中，以便我可以具体引用每个值。但是，我尝试实现的哈希表代码无法达到我的预期目的：

 my %hash;



foreach $file(@file) {


    $name = $file=~ /(\w*)_testing_42/; #comes from file path
    $name = 1$;
    print $name; #prints G43B76P90T45



    my($first $second $third $fourth) = $name;
    $hash{"first"} = $first;
    $hash{"second"} = $second;
    $hash{"third"} = $third;
    $hash{"fourth"} = $fourth;

预期输出：

    print $fourth; #should print T45


    print $first; #should print G43
    print $third #should print  P90
}

Answer 1

首先您需要将名称分成 4 部分：

my ($first, $second, $third, $fourth) = unpack("(A3)*", $name);

填充哈希

$hash{"first"} = $first;
$hash{"second"} = $second;
$hash{"third"} = $third;
$hash{"fourth"} = $fourth;

并打印哈希

print $hash{"fourth"};

Answer 2

如果我正确理解您要做什么，那么@Gever 的回答应该可以解决问题。这是使用正则表达式而不是解包的替代实现：

use 5.010;
use strict;
use warnings;

my @file = glob("/path/window/*_testing_42.csv");

foreach my $file (@file) {
    my($name) = $file =~ /(\w+)_testing_42/;
    my @code = $name =~ /(...)/g;
    say 'Parts found: ', scalar(@code);   # Parts found: 4
    say $code[0];   # G43
    say $code[1];   # B76
    say $code[2];   # P90
    say $code[3];   # T45
}

我使用数组而不是哈希，因为这对我来说更有意义，但如果你真的想要一个哈希，你可以这样做：

foreach my $file (@file) {
    my($name) = $file =~ /(\w+)_testing_42/;
    my %hash;
    @hash{'first', 'second', 'third', 'fourth'} = $name =~ /(...)/g;
    say $hash{first};   # G43
    say $hash{second};  # B76
    say $hash{third};   # P90
    say $hash{fourth};  # T45
}

在这一行：

my($name) = $file =~ /(\w+)_testing_42/;

$name 周围的括号很重要，因为它们强制在列表上下文中评估匹配，这将返回在(\w+) 中捕获的正则表达式部分。如果没有括号，值 1 将分配给 $name，因为有 1 个匹配项。

将值列表分配给散列（称为“散列切片”）中的一系列键的语法有些混乱。 Perl 知道我们将值分配给%hash，因为变量名后面有{，但是我们在变量名之前放置了@，表示我们正在为一个散列片分配多个值。在变量名前使用$ 表示我们正在分配给哈希中的单个值。

我从你的代码中改变的另一件事是我在循环中声明了%hash。这意味着您只能在循环内引用它。如果您在循环之外声明它，则在处理完每个匹配的文件名后，一组值将保持不变，但哈希可能包含来自不同文件名的值，具体取决于上次迭代中存在的字段数。