Perl 杂货程序

Question

我有一组我需要购买的杂货和一个哈希，其中杂货作为键，这些物品的成本作为值。我需要一个程序，它会根据哈希中可用的内容告诉我账单的总成本，并告诉我不可用的项目。我该怎么做呢？这是我目前所拥有的：

my %stash = ('tofu' => .30, 'berrys' => .30, 'water' => .30, 'nuts' => .30, 'chips' => .30, 'soda' => .30, 'jam' => .30, 'meat' => .30, 'kale' => .30, 'peas' => .30); 

my @itemsneeded = ('tofu', 'berrys', 'water', 'nuts', 'chips', 'rice', 'vinegar'); 

在伪代码中，我想遍历我需要的项目，如果它等于 %stash 中的键，则它会汇总这些项目的成本，如果项目不可用，则将这些名称存储在另一个变量中.然后打印出总成本和不可用的项目。到目前为止我是这样做的：

foreach my $items (@itemsneeded) {
if ($items eq 

我被困在那里。任何帮助将不胜感激！

Answer 1

首先，让事情变得理智。

use strict;
use warnings;
use v5.10;

开启strict，现在未声明的变量是一个错误。它打开warnings，所以当你做看起来像错误的事情时，Perl 会警告你。并且开启5.10 features，其中最重要的是say。

您的数据设置正确。接下来，您需要地方来存储您的全部和不可用的项目。

my $total = 0;
my @unavailable;

然后遍历您的@itemsneeded，检查哪些是可用的，并将它们的价格添加到您的$total。

for my $item (@itemsneeded) {
    if( defined $stash{$item} ) {
        $total += $stash{$item};
    }
    else {
        push @unavailable, $item;
    }
}

defined $stash{$item} 检查$item 是否在%stash 中并具有定义的值。如果有，请将其价格添加到$total。

push @unavailable, $item; 将该项目添加到 @unavailable 项目列表的末尾。

然后打印它们。需要进行一些格式化。

printf "The total cost is %.2f\n", $total;

如果你只是打印出$total，你会得到类似0.3 的东西，这不是我们写钱的方式。 %.2f 说要写精确到两个小数位的数字。 printf 有自己的小型迷你格式化语言，您可以在sprintf 的文档中阅读所有相关信息。那是 printf 但它不打印，它返回一个字符串（“s”代表“返回一个字符串”）。

然后打印出@unavailable项目列表。

say "Yes we have no ", join(", ", @unavailable), ".";

我们需要用逗号连接列表中的元素才能正确格式化。不需要换行，say 会为我们添加。