访问解码为 HASH 和哈希引用数组的 JSON

Question

鉴于以下转储程序输出，有没有办法遍历每个哈希以仅列出每个 results->id 记录下的项目？我希望能够说：

print $results{1342}{'domain'};

并让语句返回 testing11.com 作为结果。

我是否必须先通读所有 results 数组，然后使用 $results[$counter]{id} 访问其中的数据？我不确定如何继续。

$VAR1 = { 
          'end_time' => 1466017739,
          'options' => {
                         'hour_offset' => '00',
                         'timezone' => 'America/New_York'
                       },
          'field_headers' => {
                              'priority' => 'Priority',
                              'status' => 'Status',
                              'assignee_external_id' => 'Assignee external id',
                              'initially_assigned_at' => 'Initially assigned at'
                             },
          'results' => [
                         {
                           'priority' => 'High',
                           'status' => 'Open',
                           'domain' => 'testing11.com',
                           'generated_timestamp' => 1546547669,
                           'id' => 1342
                          },
                         {
                           'priority' => 'Low',
                           'status' => 'Open',
                           'domain' => 'testing22.com',
                           'generated_timestamp' => 1464567669,
                           'id' => 7062
                          },
                         {
                           'priority' => 'Low',
                           'status' => 'Closed',
                           'domain' => 'testing33.com',
                           'generated_timestamp' => 1464267669,
                           'id' => 432
                          }]
      }

Answer 1

您的转储显示包含一个标量、两个 hashref 和一个 arrayref 的 hashref。 arrayref 具有元素的 hashrefs。如果要从中检索特定元素，则需要知道索引。

$top_level->{results}->[0]->{domain};  # is 'testing11.com'
$top_level->{results}->[0]->{status};  # is 'open'

要遍历它，取消对数组的引用

foreach my $result (@{ $top_level->{results} }) {
    print "$result->{id}\n";
}

或者您可以从所有 results 元素中获取特定键的值，例如 id

my @ids = map { $_->{id} } @{ $top_level->{results} };
say "@ids";

打印

1342 7062 432

---

请注意，对于包含引用的嵌套结构，您也可以使用语法

$top_level->{results}[0]{domain};  # is 'testing11.com'  

-> 在下标之间是可选的，参见Using References in perlref 中的规则 3。

当哈希键是字符串时，它们应该被引用

$top_level->{'results'}[0]{'domain'};

但是，语法快捷方式允许我们在裸词上省略引号。但是，如果{} 中除了裸词之外还有其他任何内容，它将被解释为表达式并评估。因此，如果有任何疑问，请使用引号。您希望始终使用一致的符号。

资源：教程perlreftut，参考perlref 和数据结构说明书，perldsc。

---

stevieb 的回答中给出了直接的解决方案，创建反向查找。复制到这里供参考

my $results = $VAR1->{results};

my %by_ip = map {$_->{id} => $_} @$results;

print "$by_ip{1342}->{domain}\n";

Answer 2

您需要将内部的$results 数组转换为新的哈希：

my $results = $VAR1->{results};

my %modded = map {$_->{id} => $_} @$results;

print "$modded{1342}->{domain}\n";

输出：

testing11.com

对于@$results 中的每个哈希引用，获取id 键的值，将其设置为新哈希（%modded）中的新键，然后分配整个哈希引用我们正在处理那个编号键的值。

Answer 3

为了完整起见，如果您使用最新的 perl (use v5.24;)、后缀取消引用（默认启用）和对引用别名 (use feature 'refalias';) 的实验性支持，那么您可以取消引用 @ 987654329@ 并将其分配给别名 (%data)，然后您可以将其作为常规哈希访问：

use v5.24 ;
use feature 'refaliasing';

my $VAR1 = [AS ABOVE] ;
foreach \my %data ( $VAR1->{results}->@* ) { say $data{domain} };

我喜欢这种用法（尽管此时它远非公认的“惯用语”），因为您调用解引用语法“一次”——无论是后缀形式还是传统形式——然后在不需要的地方得到一个数据结构在块内使用->。

当然，您可以通过复制到临时哈希中来做到这一点。但别名可以被视为“更高效和可读”（cf. Data::Alias）。

---

更多参考资料：

• perl 附带的Perl Data Structures Cookbook 文档（您的shell 中的perldoc perldsc）
• 参考资料上的可访问PerlTricks article。
• brian d foy 的 introduction to use feature 'refalias' 和 perldelta 用于 5.22 版功能的条目