perl：洗牌值排序的哈希？

Question

首先对不起我的英语 - 我希望你能理解我。

有一个哈希：

$hash{a} = 1;
$hash{b} = 3;
$hash{c} = 3;
$hash{d} = 2;
$hash{e} = 1;
$hash{f} = 1;

我想按值（不是键）对其进行排序，所以我有：

for my $key ( sort { $hash{ $a } <=> $hash{ $b } } keys %hash  ) { ... }

首先我得到所有值为 1 的键，然后是值为 2，等等......太好了。

但是如果哈希没有改变，键的顺序（在这个按值排序中）总是相同的。

问题：我怎样才能打乱排序结果，所以每次我运行“for”循环时，我都会得到值 1、值 2 等不同顺序的键？

Answer 1

不太确定我是否完全理解您的需求，但这可以吗：

use List::Util qw(shuffle);

my %hash;
$hash{a} = 1;
$hash{b} = 3;
$hash{c} = 3;
$hash{d} = 2;
$hash{e} = 1;
$hash{f} = 1;

for my $key (sort { $hash{ $a } <=> $hash{ $b } } shuffle( keys %hash  )) {
    say "hash{$key} = $hash{$key}"
}

Answer 2

您可以简单地添加另一个级别的排序，当常规排序方法无法区分两个值时将使用该级别。例如：

sort { METHOD_1 || METHOD_2 || ... METHOD_N } LIST

例如：

sub regular_sort {
    my $hash = shift;
    for (sort { $hash->{$a} <=> $hash->{$b} } keys %$hash) {
        print "$_ ";
    };
}
sub random_sort {
    my $hash = shift;
    my %rand = map { $_ => rand } keys %hash;
    for (sort { $hash->{$a} <=> $hash->{$b} ||
        $rand{$a} <=> $rand{$b} } keys %$hash ) {
        print "$_ ";
    };
}

Answer 3

要按值对键进行排序，对具有相同值的键进行随机排序，我看到了两种解决方案：

use List::Util qw( shuffle );
use sort 'stable';
my @keys =
   sort { $hash{$a} <=> $hash{$b} }
   shuffle keys %hash;

或

my @keys =
   map $_->[0],
   sort { $a->[1] <=> $b->[1] || $a->[2] <=> $b->[2] }
   map [ $_, $hash{$_}, rand ],
   keys %hash;

---

需要use sort 'stable'; 以防止sort 破坏shuffle 返回的列表的随机性。

---

上面对Schwartzian Transform 的使用不是优化的尝试。我见过有人在比较函数本身中使用rand 来尝试达到上述结果，但这样做有两个问题。

当使用诸如此类的“行为不端”比较时，结果被记录为未定义，因此允许sort 返回垃圾、重复元素、缺失元素等。

即使sort 不返回垃圾，它也不会是一个公平的排序。结果将被权衡。

Answer 4

你可以有两个函数用于升序和降序，并相应地使用它们

sub hasAscending {
   $hash{$a} <=> $hash{$b};
}

sub hashDescending {
   $hash{$b} <=> $hash{$a};
}

foreach $key (sort hashAscending (keys(%hash))) {
   print "\t$hash{$key} \t\t $key\n";
}

foreach $key (sort hashDescending (keys(%hash))) {
   print "\t$hash{$key} \t\t $key\n";
}

Answer 5

您似乎想通过键随机循环。

Perl 不按顺序或排序顺序存储，但这对您来说似乎不够随机，因此您可能希望创建一个键数组并循环遍历它。

首先，用键填充一个数组，然后使用随机数算法 (1..$#length_of_array) 将数组中该位置的键推送到 array_of_keys。

---

如果您尝试随机化按值排序的哈希的键，那就有点不同了。

See Codepad

my %hash = (a=>1, b=>3, c=>3, d=>2, e=>1, f=>1);
my %hash_by_val;

for my $key ( sort { $hash{$a} <=> $hash{$b} } keys %hash ) { 
   push @{ $hash_by_val{$hash{$key}} }, $key;
}


for my $key (sort keys %hash_by_val){
   my @arr        = @{$hash_by_val{$key}};
   my $arr_ubound = $#arr;

   for (0..$arr_ubound){
      my $randnum = int(rand($arr_ubound));
      my $val     = splice(@arr,$randnum,1);
      $arr_ubound--;
      print "$key : $val\n";                    # notice: output varies b/t runs
   }
}