Perl从数组中输出连续的字符串

Question

我有一个可以打印为“abcd”的数组，但是我试图将其打印为“a>ab>abc>abcd”。我无法在我拥有的 foreach 循环中找出我需要的嵌套循环。我需要在其中使用什么循环才能以这种方式打印它？

my $str = "a>b>c>d";
my @words = split />/, $str;

foreach my $i (0 .. $#words) {
print $words[$i], "\n";
}

谢谢。

Answer 1

您的想法是正确的，但您不想打印位置 i 处的单词，而是想要打印位置 0 和 i（包括）之间的所有单词。此外，您的输入可以包含多个字符串，因此请遍历它们。

use warnings;

while (my $str = <>) {              # read lines from stdin or named files
  chomp($str);                      # remove any trailing line separator

  my @words = split />/, $str;      # break string into array of words
  foreach my $i (0 .. $#words) {
    print join '', @words[0 .. $i]; # build the term from the first n words
    print '>' if $i < $#words;      # print separator between terms (but not at end)
  }

  print "\n";
}

还有许多其他的编写方式，但希望这种方式可以帮助您了解正在发生的事情以及原因。祝你好运！

Answer 2

一个班轮：

perl -e '@a=qw(a b c d); for(@a) {$s.=($h.=$_).">"} $s=substr($s,0,-1);print $s'

Answer 3

我会这样做：

#!/usr/bin/perl

use strict;
use warnings;

my $str = "a>b>c>d>e>f>g";
my @words = split />/, $str;

$" = '';
my @new_words;

push @new_words, "@words[0 .. $_]" for 0 .. $#words;

print join '>', @new_words;

需要解释一些事情。

Perl 将在双引号字符串中展开数组变量。所以是这样的：

@array = ('x', 'y', 'z');
print "@array";

将打印x y z。注意元素之间有空格。插入元素之间的字符串由$" 变量控制。因此，通过将该变量设置为空字符串，我们可以删除空格，所以：

$" = '';
@array = ('x', 'y', 'z');
print "@array";

将打印xyz。

最复杂的一行是：

push @new_words, "@words[0 .. $_]" for 0 .. $#words;

这只是一种简洁的书写方式：

for (0 .. $#words) {
  my $new_word = "@words[0 .. $_]";
  push @new_words, $new_word;
}

我们遍历整数从零到@words 中的最后一个索引。每次循环时，我们使用数组切片从数组中获取元素列表，将其转换为字符串（通过将其放在双引号中），然后将该字符串推送到 @new_words。

Answer 4

这就是我最终得到的结果，这是我能够理解并获得我正在寻找的输出的唯一方法。

use strict;
use warnings;

my $str = "a>b>c>d>e>f>g";
my @words = split />/, $str;

my $j = $#words;
my $i = 0;
my @newtax; 
while($i <= $#words){
        foreach my $i (0 .. $#words - $j){
            push (@new, $words[$i]);
    }

    if($i < $#words){
        push(@new, ">");
    }
    $j--;
    $i++;
}

print @new;

这个输出“a>ab>abc>abcd>abcde>abcdef>abcdefg”