为什么我只得到第一个捕获组？

Question

（https://stackoverflow.com/a/2304626/6607497 和 https://stackoverflow.com/a/37004214/6607497 没有帮助我）

在 Linux 中分析/proc/stat 的问题 我开始编写一个小实用程序，但我无法按照我想要的方式获取捕获组。 代码如下：

#!/usr/bin/perl
use strict;
use warnings;

if (open(my $fh, '<', my $file = '/proc/stat')) {
    while (<$fh>) {
        if (my ($cpu, @vals) = /^cpu(\d*)(?:\s+(\d+))+$/) {
            print "$cpu $#vals\n";
        }
    }
    close($fh);
} else {
    die "$file: $!\n";
}

例如，通过这些输入行，我得到了输出：

> cat /proc/stat
cpu  2709779 13999 551920 11622773 135610 0 194680 0 0 0
cpu0 677679 3082 124900 11507188 134042 0 164081 0 0 0
cpu1 775182 3866 147044 38910 135 0 15026 0 0 0
cpu2 704411 3024 143057 37674 1272 0 8403 0 0 0
cpu3 552506 4025 136918 38999 160 0 7169 0 0 0
intr 176332106  ...

 0
0 0
1 0
2 0
3 0

所以匹配确实有效，但我没有将捕获组放入@vals（perls 5.18.2 和 5.26.1）。

Answer 1

仅捕获单个模式中的最后一个重复匹配项。

相反，可以只拆分行，然后检查 -- 并调整 -- 第一个字段

while (<$fh>) {
    my ($cpu, @vals) = split;
    next if not $cpu =~ s/^cpu//;
    print "$cpu $#vals\n";
}

如果split 的返回的第一个元素不是以cpu 开头，则正则表达式替换失败，因此该行被跳过。否则，您将得到cpu 后面的数字（或空字符串），如 OP 中所示。

或者，可以使用您处理的行的特定结构

while (<$fh>) {
    if (my ($cpu, @vals) = map { split } /^cpu([0-9]*) \s+ (.*)/x) { 
        print "$cpu $#vals\n";
    }
}

正则表达式返回两个项目，每个项目都是map 中的split，除了第一个项目按原样传递给$cpu（是一个数字或一个空字符串），而另一个产生数字。

这两种方法都会在我的测试中产生所需的输出。

Answer 2

按照示例输入，while 循环中的以下内容应该可以工作。

if (/^cpu(\d*)/) {
    my $cpu = $1;
    my (@vals) = /(?:\s+(\d+))+/g;
    print "$cpu $#vals\n";
}

Answer 3

在Learning Perl 的练习中，我们陈述了一个用两个简单的正则表达式很容易解决但用一个很难解决的问题（但是在Mastering Perl 中，我拿出了大手笔）。我们不会告诉人们这一点，因为我们想强调尝试在单个正则表达式中编写所有内容的自然行为。其他答案中的一些扭曲让我想起了这一点，我不想保留其中任何一个。

首先，存在仅处理有趣行的问题。然后，一旦我们有了那条线，抓住所有的数字。将该问题陈述翻译成代码非常简单明了。这里没有杂技，因为断言和锚点完成了大部分工作：

use v5.10;

while( <DATA> ) {
    next unless /\A cpu(\d*) \s /ax;
    my $cpu = $1;
    my @values = / \b (\d+) \b /agx;
    say "$cpu " . @values;
    }

__END__
cpu  2709779 13999 551920 11622773 135610 0 194680 0 0 0
cpu0 677679 3082 124900 11507188 134042 0 164081 0 0 0
cpu1 775182 3866 147044 38910 135 0 15026 0 0 0
cpu2 704411 3024 143057 37674 1272 0 8403 0 0 0
cpu3 552506 4025 136918 38999 160 0 7169 0 0 0
intr 176332106  ...

请注意，OP 仍然必须决定如何处理没有尾随数字的 cpu 案例。不知道你想对空字符串做什么。

Answer 4

Perl 的正则表达式引擎只会记住重复表达式中的 last 捕获组。如果您想在单独的捕获组中捕获每个数字，那么一种选择是使用显式正则表达式模式：

if (open(my $fh, '<', my $file = '/proc/stat')) {
    while (<$fh>) {
        if (my ($cpu, @vals) = /^cpu(\d*)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)\s+(\d+)$/) {
            print "$cpu $#vals\n";
        }
    }
    close($fh);
} else {
    die "$file: $!\n";
}

Answer 5

更换

    while (<$fh>) {
        if (my ($cpu, @vals) = /^cpu(\d*)(?:\s+(\d+))+$/) {

与

    while (<$fh>) {
        my @vals;
        if (my ($cpu) = /^cpu(\d*)(?:\s+(\d+)(?{ push(@vals, $^N) }))+$/) {

做我想做的事（需要 perl 5.8 或更高版本）。

Answer 6

他是我的榜样。我想我会添加它，因为我喜欢简单的代码。它还允许“cpu7”没有尾随数字。

#!/usr/bin/perl
use strict;
use warnings;

my $file = "/proc/stat";
open(my $fh, "<", $file) or die "$file: $!\n";
while (<$fh>) 
{
  if ( /^cpu(\d+)(\s+)?(.*)$/ ) 
  {
    my $cpu = $1; 
    my $vals = scalar split( /\s+/, $3 ) ;
    print "$cpu $vals\n";
  }
}
close($fh);

Answer 7

只需添加到Tim's answer：

您可以使用一组捕获多个值（使用 g 修饰符），但是您必须拆分语句。

    if (my ($cpu) = /^cpu(\d*)(?:\s+(\d+))+$/) {
        my @vals= /(?:\s+(\d+))/g;
        print "$cpu $#vals\n";
    }