从数组创建散列的多维键？

Question

我想从@array 创建一个多维%hash。

假设@array 就像

my @array=(1,2,3,4,5);

我想将@array最后一个值作为最终值分配给多维%hash，即

%hash=(
        1=>{ 
              2=>
                 {
                  3=>
                      {
                        4=>5
                       }
                  }
              }
           )

这意味着$hash{1}{2}{3}{4}=5;

我想这样做：

for my $i (0..$#array){
    #push $i as key until second last element and assign last element as value
} 

注意：@array 可以是任意大小，只是我想将@array 的最后一个元素作为值分配给%hash 中最后一个元素之前的元素键。

Answer 1

首先，使用pop 将要分配的值与键分开。然后，您可以使用以下任一方法：

use Data::Diver qw( DiveVal );

my %hash;
DiveVal(\%hash, map \$_, @keys) = $val;

或

sub dive_val :lvalue {
   my $p = \shift;
   $p = \( $$p->{$_} ) for @_;
   $$p
}

my %hash;
dive_val(\%hash, @keys) = $val;

dive_val 的工作原理是让 $p 引用下一个值以取消引用和/或修改。

Pre-loop:            $p references $hash (the anon scalar referencing %hash)
After loop pass 0:   $p references $hash->{1}
After loop pass 1:   $p references $hash->{1}{2}
After loop pass 2:   $p references $hash->{1}{2}{3}
After loop pass 3:   $p references $hash->{1}{2}{3}{4}

额外的间接层有很多好处。

• 它消除了对最后一个键进行特殊处理的需要。
• 它消除了在取消引用之前创建散列的需要。
• 它不再需要根作为对哈希的引用。相反，任何标量都可以是根，甚至是未定义的。
• 它可以轻松扩展 dive_val 以支持混合数组/哈希结构。