如何列出给定范围内的所有变量？

Question

我知道我可以使用Padwalker 的peek_our 和peek_my 列出给定范围内的所有包变量和词法变量，但是如何获取所有全局变量的名称和值，例如@ 987654325@和$/?

#!/usr/bin/perl

use strict;
use warnings;

use PadWalker qw/peek_our peek_my/;
use Data::Dumper;

our $foo = 1;
our $bar = 2;

{
    my $foo = 3;
    print Dumper in_scope_variables();
}

print Dumper in_scope_variables();

sub in_scope_variables {
    my %in_scope = %{peek_our(1)};
    my $lexical  = peek_my(1);
    #lexicals hide package variables
    while (my ($var, $ref) = each %$lexical) {
        $in_scope{$var} = $ref;
    }
    ##############################################
    #FIXME: need to add globals to %in_scope here#
    ##############################################
    return \%in_scope;
}

Answer 1

您可以访问符号表，请查看 p。 《Perl 编程》第 293 章 另请参阅“精通 Perl：http://www252.pair.com/comdog/mastering_perl/ 具体：http://www252.pair.com/comdog/mastering_perl/Chapters/08.symbol_tables.html

您要查找的变量将位于主命名空间下

快速的 Google 搜索给了我：

{
    no strict 'refs';

    foreach my $entry ( keys %main:: )
    {
        print "$entry\n";
    }
}

你也可以这样做

*sym = $main::{"/"}

对于其他值也是如此

如果你想找到你可以做的符号类型（来自掌握 perl）：

foreach my $entry ( keys %main:: )
{
    print "-" x 30, "Name: $entry\n";

    print "\tscalar is defined\n" if defined ${$entry};
    print "\tarray  is defined\n" if defined @{$entry};
    print "\thash   is defined\n" if defined %{$entry};
    print "\tsub    is defined\n" if defined &{$entry};
}

Answer 2

就是这样。感谢 MGoDave 和 kbosak 在我面前提供了我太愚蠢以至于看不到的答案（我开始查看 %main:: ，但错过了他们没有他们的印记）。完整代码如下：

#!/usr/bin/perl

use strict;
use warnings;

use PadWalker qw/peek_our peek_my/;
use Data::Dumper;

our $foo = 1;
our $bar = 2;

{
    my $foo = 3;
    print Dumper in_scope_variables();
}

print Dumper in_scope_variables();

sub in_scope_variables {
    my %in_scope = %{peek_our(1)};
    my $lexical  = peek_my(1);
    for my $name (keys %main::) {
        my $glob = $main::{$name};
        if (defined ${$glob}) {
            $in_scope{'$' . $name} = ${$glob};
        }

        if (defined @{$glob}) {
            $in_scope{'@' . $name} = [@{$glob}];
        }

        if (defined %{$glob}) {
            $in_scope{'%' . $name} = {%{$glob}};
        }
    }

    #lexicals hide package variables
    while (my ($var, $ref) = each %$lexical) {
        $in_scope{$var} = $ref;
    }
    return \%in_scope;
}

Answer 3

您可以执行以下操作来检查主包的符号表：

{
    no strict 'refs';

    for my $var (keys %{'main::'}) {
        print "$var\n";
    }
}

Answer 4

谢谢，Chas，非常有用的代码。 作为 perl > 5.12 代码的未来用户的说明：

我在我的 pdl2 .perldlrc 中使用它来查找词法变量（如调试器中的 'y' 命令），我收到了以下警告：

load_rcfile: 加载

/homes/pmg/.perldlrc defined(%hash) 在 (eval 254) 第 36 行已弃用。

    (Maybe you should just omit the defined()?)

从 perldoc -f 定义

使用定义的聚合（散列 和数组）已弃用。它曾经 报告是否有记忆 聚合曾经被分配过。 这种行为将来可能会消失 Perl 的版本。你应该改为 使用简单的大小测试：

>     if (@an_array) { print "has array elements\n" }
>     if (%a_hash) { print "has hash members\n" }

我不明白的是为什么它只抱怨定义的哈希而不是数组？