如何使用 Perl 按行和列组织数据？

Question

基本问题是我有很多具有标准化名称的数据点，这些数据点刚刚从服务器转储到文件中，但我需要根据它们包含的数据自动将这些数据点组织到具有行和列的文件中（以它们的标准化名称表示）。

---

包含所有数据点的原始文件如下（这些不是原始数据点标签，而是简化的标签）：

temp_r301
airflow_r301
temp_r345
airflow_r345
solar_w
solar_e
...

如您所见，它们都以一列的形式出现，因此每行有一个标签。

我想对它们进行组织，以便对于每个状态（“温度”，如温度），我在同一行中有相应的信息，例如：

temp_r301 301 airflow_r301 solar_w solar_e     #airflow in 301 and general solar radiation affect temperature (state) in room 301
temp_r345 345 airflow_r345 solar_w solar_e     #airflow in 345 and general solar radiation affect temperature (state) in room 345

当然，数组的长度可能会有所不同，因此我们的想法是制定一种算法来检测长度并相应地组织数据。另外，我知道我必须使用正则表达式来查找匹配项并定义哪些数据点是状态，哪些是输入，以及知道它们所属的房间。

---

到目前为止，我已经尝试了以下方法：

use strict;
use warnings;
use diagnostics;

my @transpose = ();
my @sorted = ();

push(@sorted, [qw(temp_r301 temp_r345)]);
push(@sorted, [qw(301 345)]);
push(@sorted, [qw(airflow_r301 airflow_r345 solar_w solar_e)]);

for my $sorted (@sorted) {
  for my $column (0 .. $#sorted) {
    push(@{$transpose[$column]}, $sorted->[$column]);
  }
}

for my $new_row (@transpose) {
  for my $new_col (@{$new_row}) {
      print "$new_col ";
  }
  print "\n";
}

但这只有在所有数组都具有相同长度的情况下才能正常工作（不是这种情况）。

我还发现了一个循环，可用于将数据存储为矩阵形式（数组的数组），但我似乎仍然无法找到将来自不同数组的数据写入矩阵的解决方案：

use strict;
use warnings;
use diagnostics;
use feature 'say';

my @states = qw(temp_r301 temp_r345);
my @zones = qw(301 345);
my @inputs = qw(airflow_r301 airflow_r345 solar_w solar_e);

my @matrix = ();

for my $x (0 .. $#states) {
    for my $y (0 .. $#inputs) {
        $matrix[$x][$y] = $states[$x];           #of course this only copies the states array and
    }                                            #repeats it for each created array
}

for my $aref (@matrix) {                         #print array of arrays
    say "[ @$aref ],";
}

那么，知道我已将所有数据转储到输入文件中，将这些数据排序到矩阵中的最佳方法是什么？有没有我应该更加注意的循环？我应该使用数组吗？

Answer 1

这个问题的细节还不清楚，但解释确实有帮助。所以这就是我的假设。

我获取数据以使每行有一条信息。有些包含一个标签（描述），后跟房间号，我假设格式为tag_rN，标识标签适用的房间号。

对于没有房间号的其他人，需要进行额外处理来确定该信息所属的位置。这个问题只提出了一个适用于所有房间的标签示例，与影响它们的太阳辐射有关（参见 cmets），所以这就是所有已处理的内容。

某些数据没有整齐地与房间分类这一事实使得解析数据的组织变得不重要。由于没有给出详细信息，我只是将其分成两个散列，一个按房间号，另一个根据具体结构而定。

use warnings;
use strict;
use feature 'say';
use Data::Dump qw(dd);

my $file = shift // die "Usage: $0 file\n";
open my $fh, '<', $file or die "Can't open $file: $!";

my (%room, %other);
while (<$fh>) { 
    chomp;
    if ( my ($tag, $room_num) = /([^_]+)_r([0-9]+)/ ) {
        $room{$room_num}{$tag} = $_;                  # have room number
    }
    else {                                            # more processing needed
        my ($tag, $value) = parse_line($_);
        push @{ $other{$tag} }, $value;
    }
}
dd \%room; dd \%other; say '';

# Print in CSV format. Header first
my @tags = ( keys %{ $room{ (keys %room)[0] } }, keys %other );
say join ',', 'room', @tags;
foreach my $rnum (keys %room) { 
    say join ',', 
        $rnum, map { $room{$rnum}{$_} // join ' ', @{$other{$_}}  } @tags;
}

sub parse_line {
    my ($line) = @_;
    my ($tag, $value);

    if ($line =~ /solar_w|solar_e/) {   # example from sample data
        $tag   = 'solar';
        $value = $line;
    }
    else { }  # other possibilities

    return $tag, $value;
}

带有房间号的数据以标识描述（“标签”）为键排序，行为其值。每个这样的键值对都在分配给每个房间号的 hashref 中。

没有房间号的数据在一个单独的子中被解析，只有一些令牌代码，因为没有给出细节。然后将其存储在另一个哈希中，以便于操作（因为它不绑定到任何一个房间）。

如何从数据中提取标签有点随意，因为问题中没有指定。

所有这些都组合成 CSV 格式。以上，带有来自问题的输入文件和 cmets 中的解释，即来自西方和东方的太阳辐射会影响所有房间，打印：

{
  301 => { airflow => "airflow_r301", temp => "temp_r301" },
  345 => { airflow => "airflow_r345", temp => "temp_r345" },
}
{ solar => ["solar_w", "solar_e"] }

room,airflow,temp,solar
345,airflow_r345,temp_r345,solar_w solar_e
301,airflow_r301,temp_r301,solar_w solar_e

用dd ...（来自Data::Dump）注释掉该行以删除初始诊断打印。然后最后几行是CSV，将进入某个文件等。

某些房间的某些数据可能会丢失，还有更多的数据可能无法如此统一地分类。然后，根据需要，这些标题的字段在某些行中将是空的。