通过 Terraform 验证 SSL 的问题

Question

帮助了解我的 terraform 模块发生了什么 通常它可以正常工作，它会正确创建 SSL 证书和 Route53 记录 但是验证步骤失败不知道为什么，因为记录已成功创建，但仍然收到未找到记录的错误：

aws_acm_certificate_validation.this： 正在创建... ╷ │ 错误：1 个错误 发生：│ *缺少 course.com DNS 验证记录： _7eaea1fef0f356222c22a6bc1eb7bbd7.course.com

resource "aws_acm_certificate" "this" {
  domain_name       = var.domain
  validation_method = var.validation_method

  tags = {
    Name = var.domain,
    Environment = var.environment
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_acm_certificate_validation" "this" {
  certificate_arn         = aws_acm_certificate.this.arn
  validation_record_fqdns = var.fqdn_records[*]
}

resource "aws_route53_record" "this" {
  for_each = {
    for dvo in aws_acm_certificate.this.domain_validation_options : dvo.domain_name => {
      name    = dvo.resource_record_name
      record  = dvo.resource_record_value
      type    = dvo.resource_record_type
      zone_id = var.zone_id
    }
  }

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 300
  type            = each.value.type
  zone_id         = each.value.zone_id
}

附：不确定，但可能是它试图在我的区域（使用 eu-central-1）找到 dns 记录但仍然不知道如何更正修复它的问题

Answer 1

你可以试试：

resource "aws_acm_certificate_validation" "cert_validation" {
  certificate_arn         = aws_acm_certificate.this.arn
  validation_record_fqdns = [for record in aws_route53_record.this : record.fqdn]
}