循环列表列表

Question

我有一个aws_route 资源，我想用新路由更新列表中的所有路由表。以下是相关代码：

resource "aws_route" "private_route" {
  for_each = data.aws_route_tables.private_route_tables.ids

  route_table_id          = each.key
  destination_cidr_block  = var.tgw_destination_cidr_block
  transit_gateway_id      = module.tgw.ec2_transit_gateway_id
}

当变量tgw_destination_cidr_block 中定义了一个CIDR 时，上述代码可以正常工作，因为aws_route 需要destination_cidr_block 属性的字符串类型。

tgw_destination_cidr_block = "10.255.160.0/20"

现在我想在这个变量中添加多个 CIDR 范围，并对其进行迭代。

tgw_destination_cidr_block = ["10.255.160.0/20", "10.255.176.0/22"]

为了在每个路由表中创建两条新路由。所以，我想我需要变量中的字符串列表并遍历 CIDR 范围列表。

知道怎么做吗？

Answer 1

在考虑for_each 表达式时，我总是首先考虑“为每个...声明一个实例”这句话的结尾可能是什么，在这种情况下，这句话似乎是：

为每一对私有路由表和目标 CIDR 块声明一个实例。

这告诉我们，我们需要一个集合，其中每个元素代表其中一对。

查找多组项目的所有组合的常用方法是the setproduct function，其文档中有一个部分Finding combinations for for_each 显示了为许多不同的基础网络声明一组系统子网的工作示例.

我们可以根据您的问题调整该示例，如下所示。文档中的示例已经通过小步骤完成了它，因此为了简单起见，我将在这里将所有本地值表达式合并为一个：

locals {
  route_table_routes = [
    for pair in setproduct(data.aws_route_tables.private_route_tables.ids, var.tgw_destination_cidr_blocks) : {
      route_table_id         = pair[0]
      destination_cidr_block = pair[1]
    }
  ]
}

resource "aws_route" "private_route" {
  for_each = {
    for rtr in local.route_table_routes : "${rtr.route_table_id}:${rtr.destination_cidr_block}" => rtr
  }

  route_table_id          = each.value.route_table_id
  destination_cidr_block  = each.value.destination_cidr_block
  transit_gateway_id      = module.tgw.ec2_transit_gateway_id
}

上面将声明 aws_route.private_route 实例，其键是路由表 ID 和目标 CIDR 块的组合。

请注意，将远程系统分配的 id 用作 Terraform 中实例键的一部分可能会出现问题，因为 Terraform 需要在整个计划和应用过程中完全知道这些实例键。但是，在您的情况下，您正在使用数据源检索这些路由表 ID，因此只要在规划期间可以完全了解您的数据资源配置本身，它们就会在规划期间为人所知。

通常我建议使用相同的配置来负责声明路由表和这些路由，从而能够为每个路由表提供一个完全从配置中知道的静态密钥（不是由远程系统决定）全部），但是这种设计在分解的系统中并不总是实用的，因此只要您注意确保以正确的顺序将更改应用于单独的 Terraform 配置，您在这里所做的事情就可以了这样更改将以您想要的方式级联，即使 Terraform 无法看到整个依赖结构，因此无法保证排序本身。