QML组件碰撞测试方法

Question

嗯，可能有很多 QML 程序，如果两个组件相互碰撞，程序员会根据它定义一个动作。在下面这样的程序中，我们希望专注于碰撞，并尝试知道如何定义一个函数来告诉我们是否发生了这种碰撞。

下面的代码是一个更大程序的一部分。为此，我尝试在代码中使用一个名为 collision 的函数。到目前为止的问题是它运行得不好。我想知道 QML 中是否有内置函数“或”是否有用于此目的的好代码。

球拍有三个可能与球发生碰撞的面：前面的一个长面，一个上部和一个下部。具体的问题是，当球从上表面或下表面与球拍碰撞时，球会进入球拍内部！
我要解决的问题是。我希望当球从任何面击中球拍时，它会反射。

main.qml:

import QtQuick 2.9
import QtQuick.Window 2.2

Window {
    visible: true
    width: 720
    height: 620
    title: qsTr("Collision Test")

    Rectangle {
        id: table
        anchors.fill: parent
        color: "gray"

        Rectangle {
            id: ball
            property double xincrement: Math.random() + 0.5
            property double yincrement: Math.random() + 0.5
            width: 15
            height: width
            radius: width / 2
            color: "white"
            x: 300; y: 300
        }

        Racket {
            id: myRacket
            x: table.width - 50
            y: table.height/3
            color: "blue"
        }

        Timer {
            interval: 5; repeat: true; running: true

            function collision() {
                if((ball.x + ball.width >= myRacket.x  &&
                    ball.x < myRacket.x + myRacket.width) &&
                   (ball.y + ball.height >= myRacket.y &&
                    ball.y <= myRacket.y + myRacket.height))
                    return true
                return false
            }

            onTriggered: {
                if(ball.x + ball.width >= table.width)
                    running = false

                else if(ball.x <= 0)
                    ball.xincrement *= -1

                else if (collision())
                    ball.xincrement *= -1

                ball.x = ball.x + (ball.xincrement * 1.5);
                ball.y = ball.y + (ball.yincrement * 1.5);

                if(ball.y <= 0 || ball.y + ball.height >= table.height)
                    ball.yincrement *= -1
            }
        }
    }
}

Racket.qml：

import QtQuick 2.9

Rectangle {
    id: root
    width: 15; height: 50

    MouseArea {
        anchors.fill: parent
        drag.target: root
        drag.axis: Drag.YAxis
        drag.minimumY: table.y
        drag.maximumY: table.y + table.height - 50
    }
}

Answer 1

对于简单的检查，一个点是否在Item 内，您可以使用contains(point p)。

这个函数需要一个局部坐标点，（相对于Items原点），所以你应该使用mapFromItem(...)或mapToItem(...)来获得正确的位置。