如何在openge 4gl中找到由分隔符分隔的字符串的索引？答案

【问题标题】：How to find the index of the string separated by delimeters in progress openedge 4gl?如何在openge 4gl中找到由分隔符分隔的字符串的索引？
【发布时间】：2016-07-12 23:07:15
【问题描述】：

我想在 "STS++5623+56+ 123 " 中找到 56 的索引。我写的代码给了我 6 个（共 5623 个），但我需要 11 个。

DEFINE var v-segment as longchar no-undo. 
DEFINE VARIABLE v-element AS CHARACTER   NO-UNDO.
ASSIGN v-segment = "STS++5623+56".
ASSIGN v-element = "56".

define variable v-index as integer no-undo.

v-index = index(v-segment , v-element , 1).

MESSAGE v-index
     VIEW-AS ALERT-BOX INFO BUTTONS OK.

【问题讨论】：

您的标题显示“由分隔符分隔”。但是问题的主体并没有说明分隔符是什么以及为什么它们很重要。您也没有解释为什么您对 6 不满意，以及是什么让 11 成为更好的答案。解释您的需求的一种方法是您想要“56”的第二个实例而不是第一个实例。但我怀疑现实比这更复杂。

标签： string indexing progress-4gl openedge

【解决方案1】：

抱歉，之前的答案不是您需要的。我决定保留它，因为它是解决上述问题的好方法。但我会再试一次。我将分隔符的检查设置为一个单独的功能，以便您可以轻松地将其调整为您的要求。添加多字节字符功能应该很简单。

DEFINE VARIABLE v-segment    AS LONGCHAR  NO-UNDO.
DEFINE VARIABLE v-element    AS CHARACTER NO-UNDO.
DEFINE VARIABLE v-delims     AS CHARACTER NO-UNDO.

DEFINE VARIABLE v-index      AS INTEGER   NO-UNDO.
DEFINE VARIABLE v-delimCount AS INTEGER   NO-UNDO.
DEFINE VARIABLE v-segLength  AS INTEGER   NO-UNDO.
DEFINE VARIABLE v-eltLength  AS INTEGER   NO-UNDO.
DEFINE VARIABLE v-psn        AS INTEGER   NO-UNDO.

ASSIGN v-segment    = "STS++5623+56"
       v-element    = "56"
       v-delims     = "+:"
       /* For efficiency, don't calculate these inside your loop */
       v-seglength  = LENGTH( v-segment)
       v-eltLength  = LENGTH( v-element)
       v-delimCount = LENGTH( v-delims).


/*
** isDelin()
** Is character at specified positiion one of the delimiters?
**
**   Params:
**   CHARACTER p-str    - string to search
**   INTEGER   p-psn    - position to check
**   CHARACTER p-delims - list of delimiters to check for
**
** Returns TRUE if character at specified position is a delimiter
** Otherwise, returns FALSE
*/
FUNCTION isDelim RETURNS LOGICAL (
  INPUT p-str     AS LONGCHAR,
  INPUT p-psn     AS INTEGER,
  INPUT p-delims  AS CHARACTER
):

  /* You might want parameter checking here.... */
  RETURN INDEX( p-delims, SUBSTRING( p-str, p-psn, 1)) > 0.

END FUNCTION.  /* isDelim */

/*
** You might want special case handling here:
**   if v-eltLength = 0 then v-index = 1.  return.
**   IF v-element = ? or v-segment = ? then v-index = 0.  return.
*/

/* Look for v-element, then see if it is surrounded by delimiters */
v-index = 0.
DO WHILE TRUE:

  v-index = INDEX( v-segment, v-element, v-index + 1).
  If v-index = 0 THEN LEAVE.   /* No more matches */

  /*
  ** Found a match.  Is it preceded by a delimiter?
  ** (Don't check if match is at beginning of string.)
  */
  v-psn = v-index - 1.
  IF v-psn > 0 AND NOT isDelim( v-segment, v-psn, v-delims) THEN NEXT.

  /*
  ** Is match followed by a delimiter?
  ** (Don't check if match is at end of string.)
  */
  v-psn = v-index + v-eltLength.
  IF v-psn > v-seglength THEN LEAVE.

  IF NOT isDelim(v-segment, v-psn, v-delims) THEN NEXT.

  /* Success! */
  LEAVE.
END.

MESSAGE v-index VIEW-AS ALERT-BOX INFO BUTTONS OK.

【讨论】：

谢谢，正是我想要的:)
很高兴听到这个消息。您应该检查答案以将其标记为已解决；这将使以后的搜索更容易找到它。

【解决方案2】：

有几种方法可以解决这个问题。哪个最聪明取决于数据。我可以想到两个不涉及循环的，这可能是您正在寻找的。我没有做任何基准测试，但我认为下面的代码是最有效的算法。它最多涉及三个字符串搜索——一个entry()，一个num-entries()，一个index()。如果这不能满足您的需求，我可以提出替代方案。

DEFINE VARIABLE v-segment AS LONGCHAR  NO-UNDO.
DEFINE VARIABLE v-element AS CHARACTER NO-UNDO.
DEFINE VARIABLE v-index   AS INTEGER   NO-UNDO.
DEFINE VARIABLE v-entry   AS INTEGER   NO-UNDO.
DEFINE VARIABLE v-delim   AS CHARACTER NO-UNDO.

ASSIGN v-segment = "STS++5623+56"
       v-element = "56"
       v-delim   = "+".

/* Does the segment contain the exact entry? */
v-entry = LOOKUP(v-element, v-segment, v-delim).

/*
** If entry number = 0, then element is not found
** If entry number = 1, then element is at beginning of segment.
** If entry number = num-entries(), then element is at end of segment
** Otherwise, element is in the middle; just search for it surrounded
**    by delimters.
*/

IF v-entry = 0 THEN
  v-index = 0.
ELSE IF v-entry = 1 THEN 
  v-index = 1.
ELSE IF v-entry = NUM-ENTRIES( v-segment, v-delim) THEN  
  v-index = R-INDEX( v-segment, v-delim) + 1.
else                                                     
  v-index = INDEX( v-segment, v-delim + v-element + v-delim) + 1.

MESSAGE v-index VIEW-AS ALERT-BOX INFO BUTTONS OK.

【讨论】：

这不适用于 "STS++5623+::56" ， : 是另一个分隔符。我忘了提：可以是另一个可能的分隔符，
该问题的任何其他重要方面？特别是：所有分隔符都是单个字符吗？
另外：您是否需要支持多字节字符的解决方案，例如 UTF-8？

【解决方案3】：

DEFINE var v-segment as longchar no-undo.
DEFINE VARIABLE v-element AS CHARACTER NO-UNDO.
def var v-i as int no-undo.
def var v-data as char no-undo.

ASSIGN v-segment = "STS++5623+56+123".
ASSIGN v-element = "56".

define variable v-index as integer no-undo.

do v-i = 1 to num-entries(v-segment,"+"):

   if entry(v-i,v-segment,"+") = v-element then
  do:

     v-data = entry(v-i,v-segment,"+").

     MESSAGE v-data VIEW-AS ALERT-BOX INFO BUTTONS OK.

     end.

end.

【讨论】：