在 Delphi XE2 中将 Windows 图元文件转换为位图时文本模糊

Question

我正在开发一个 Delphi XE2 程序，它需要能够将 Windows 增强的元文件转换为位图。以下代码用于执行转换：

procedure TForm1.Button8Click(Sender: TObject);
var
  Bitmap : TBitmap;
  Metafile : TMetafile;
begin
  Metafile := TMetafile.Create();
  Bitmap := TBitmap.Create;
  try
    Metafile.LoadFromFile(Edit1.Text);
    Bitmap.Width := Metafile.Width;
    Bitmap.height:= Metafile.Height;
    Bitmap.Canvas.Draw(0,0,Metafile);
    Bitmap.SaveToFile(ChangeFileExt(Edit1.Text, '.bmp'));
  finally
    Bitmap.Free();
    Metafile.Free();
  end;
end;

对于某些图像文件，在原始图元文件中非常清晰的文本在最终位图中显得有些模糊。不幸的是，我无法在此处发布示例图像，因为我没有足够的声誉点，但是如果您在以下问题中比较这两个图像，您可以看到我正在谈论的事情：

when rendering metafile, the texts are too large

我已经在两台机器上进行了测试（都是 Windows 7；一台 32 位，另一台 64 位）。该问题仅出现在 64 位机器上；在 32 位机器上转换完全相同的图像文件会生成具有正常外观文本的位图。

到目前为止我尝试过的事情：

• 将 32 位计算机上存在但 64 位计算机上不存在的所有字体安装到 64 位计算机上。生成的位图中的文字仍然模糊。

• 尝试使用 SynGdiPlus 库而不是上述代码执行转换。生成的位图中的文字仍然模糊。

• 尝试在 EMF Explorer 中打开原始图像文件。无论是否启用 GDI+，那里显示的文字都是不模糊的。

有人对我如何解决这个问题有任何建议吗？

这是两张图片：

64位机上制作的版本：

32位机上制作的版本：

对于我正在处理的场景，我更喜欢在 32 位机器上制作的第二张图片。

Answer 1

{1} 编辑：由于我们已经确定您不是在发布此答案后创建原始元数据的人，请参阅从现有元文件中检索记录部分。

{2}编辑：关于识别字体设置的第二个问题，请参阅第二个更新部分检索字体结构记录。

ClearType 真是个泡菜。借助集成的 ClearType 调谐器，任何人都可以根据需要更改混合颜色的强度。考虑到图像，您因此不能依赖每个单独系统的 ClearType 设置。

AFAIK 唯一真正的解决方案是忽略自定义 ClearType 渲染并使用预配置的渲染。

---

编辑 1：从现有元文件中检索记录

您可以通过Enhanced Metafile Operations 更具体地通过EnumEnhMetaFile 函数修改现有元文件，该函数具有可用于处理记录的回调函数EnhMetaFileProc。

使用PlayEnhMetaFileRecord 函数一次解析并检查每条记录。 有关如何编辑和修改特定记录的更多信息，请参阅here。

在某些时候，您将不得不使用下面的代码来修改现有的字体渲染。

---

编辑2：检索字体结构记录

就像您可以通过EMREXTTEXTOUTA 结构检索位置和文本一样，您也可以通过EMREXTCREATEFONTINDIRECTW 结构检索使用的字体设置。此结构将允许您获取 LOGFONT 定义类型的字体记录，其中包含有关字体的大部分信息，但使用的画笔除外。

如果您查看我的原始答案代码，您可以看到字体的颜色是由使用的画笔定义的。所以同样你必须使用不同的结构来获取该信息，EMRCREATEBRUSHINDIRECT 结构。 LOGBRUSH32 类型成员包含有关所用画笔的颜色和样式的信息。

---

原答案

为了实现这一点，您必须使用 GDI+，因为 Win32 增强元文件的 delphi 封装不完整。使用Delphi GDI+ library。

uses 
 GDIPlus,GDIPlusHelpers

const
  Deftext = 'Lorem ipsum dolor sit amet,'
  +sLineBreak+'consectetur adipisicing elit, sed do eiusmod tempor incididunt'
  +sLineBreak+'ut labore et dolore magna aliqua.';

procedure CreateEmF(const EmfFileName : TFileName);
var
  Graphics : IGPGraphics;
  xBrush: IGPBrush;
  xFontFamily: IGPFontFamily;
  xFont: IGPFont;
  DC: HDC;
  Metafile: IGPMetafile;

begin

  xBrush := TGPSolidBrush.Create(TGPColor.Create(0, 0, 0));
  xFontFamily := TGPFontFamily.Create('Segoe UI');
  xFont := TGPFont.Create(xFontFamily, 12, FontStyleRegular, UnitPoint{UnitPixel});

  DC := GetDC(0);

  try

    Metafile := TGPMetafile.Create(EmfFileName, DC);
    Graphics := TGPGraphics.Create(Metafile);

    {
      Use Presets instead of the DefaultSystemRendering 

      TextRenderingHintAntiAliasGridFit - Preset ClearType Rendering
      TextRenderingHintSingleBitPerPixelGridFit - Preset Normal Rendering
    }

    Graphics.TextRenderingHint := TextRenderingHintAntiAliasGridFit;
    Graphics.DrawString(Deftext, xFont, TGPPointF.Create(50, 50), xBrush);

    Graphics := nil;

  finally
    ReleaseDC(0, DC);
  end;

end;

procedure ConvertEmf2Bmp(const EMFFileName, BMPFileName: TFileName) ;
var
  MetaFile : TMetafile;
  Bitmap : TBitmap;
begin
  Metafile := TMetaFile.Create;
  Bitmap := TBitmap.Create;
  try
    MetaFile.LoadFromFile(EMFFileName);
    with Bitmap do
    begin
      SetSize(MetaFile.Width,MetaFile.Height);
      Canvas.Draw(0, 0, MetaFile) ;
      SaveToFile(BMPFileName) ;
    end;
  finally
    Bitmap.Free;
    MetaFile.Free;
  end;
end;