链接来自不同工作表的数据字段

Question

我经常从 2 个不同的来源生成报告，这两个来源都有一个唯一标识符，用于链接两个报告中的数据（我将字段 ID 称为“LINK ID”）。此字段出现在两组导出中（但是导出来自填充不同数据点的 2 个不同系统）。我通常将每个报告剪切并粘贴到新创建的工作簿中的单独工作表中，然后将它们匹配起来。

有一次，我编写了一个子例程，该例程将循环浏览一张工作表中包含“LINK ID”的列，然后循环浏览另一张工作表中包含相同“LINK ID”的另一列，并且如果找到匹配项，它将复制链接到该匹配项的整行数据并将其粘贴到第一个工作表上。

我编写的代码从未完全完成，但我正在尝试看看我是否可以一劳永逸地解决这个问题，因为如果我不必用我的眼睛筛选这些代码，那就太棒了一次。

这是我所拥有的：

Private Sub Find_And_Link()

Dim rw As Long

Dim mr2 As Long

Dim ws3 As Worksheet

Set ws3 = Sheets("VM")   

With Sheets("AY")

For rw = 2 To .Cells(Rows.Count, "F").End(xlUp).Row

If CBool(Application.CountIf(ws3.Columns(1), .Cells(rw, "F").Value)) Then

mrw = Application.Match(.Cells(rw, "F"), ws3.Columns(1), 0)

ws3.Cells(mrw, "A").Resize(1, 12).Copy _
Destination:=.Cells(rw, "G")
ws3.Rows(mrw).EntireRow.Delete
'getting rid of the row if match found

End If

Next rw

End With

Set ws3 = Nothing

End Sub

Answer 1

这是我能得到的。我假设您的工作表“AY”是您希望将数据复制到 的原始工作表，而“VM”是您正在搜索要复制的数据的工作表 /em> （如果向后更改，请更改它）。我还更改了变量名称以使其更清晰：

Sub Find_And_Link()

Dim i As Long, copyRow As Long

Dim origWS As Worksheet, copyWS As Worksheet

Set copyWS = Sheets("VM")
Set origWS = Sheets("AY")

With origWS
    For i = 2 To .Cells(.Rows.Count, "F").End(xlUp).Row
        If CBool(Application.CountIf(copyWS.Columns(1), .Cells(i, "F").Value)) Then
            copyRow = Application.Match(.Cells(i, "F"), copyWS.Columns(1), 0)
            Debug.Print "Match found in row " & copyRow & "."
            copyWS.Cells(copyRow, "A").Resize(1, 12).Copy Destination:=.Cells(i, "G")
            copyWS.Rows(copyRow).EntireRow.Delete 'getting rid of the row if match found
        Else
            Debug.Print "No match found for Link ID " & .Cells(i, 6) & " :("
        End If
    Next i
End With

Set copyWS = Nothing

End Sub

我试过了，效果很好。注意：在“AY”中，您的“Link IDs”都在 F 列中。在“VM”中，“Link IDs”都在 A 列中。

这将在“VM”中找到匹配项，将数据从 A 列复制到 L，然后将其粘贴到“AY”中，从 G 到 S 列。请注意，这与您要求的不完全一致（您要求替换整个原始表中的行），但我这样做是因为它在您的代码中。

要替换原始“AY”表中的整行，请将复制目标更改为Destination:=.Cells(i,"A")。 （您可能需要在该行之前添加.Rows(i).Clear 以清除该行中的所有数据。）