Cassandra中的物化视图错误

Question

我是 Cassandra 的新手，我正在尝试创建一个表和物化视图。但它不起作用。

我的查询是：

-- 所有订单

create table all_orders (
    id uuid,
    order_number bigint,
    country text,
    store_number bigint,
    supplier_number bigint,
    flow_type int,
    planned_delivery_date timestamp,
    locked boolean,
    primary key ( order_number,store_number,supplier_number,planned_delivery_date ));

--orders_by_date

CREATE MATERIALIZED VIEW orders_by_date AS 
    SELECT 
        id,
        order_number,
        country,
        store_number,
        supplier_number,
        flow_type,
        planned_delivery_date,
        locked,
    FROM all_orders
    WHERE planned_delivery_date IS NOT NULL AND order_number IS NOT NULL 
    PRIMARY KEY ( planned_delivery_date )
    WITH CLUSTERING ORDER BY (store_number,supplier_number);

我遇到了这样的异常：

SyntaxException: <ErrorMessage code=2000 [Syntax error in CQL query]
message="line 1:7 no viable alternative at input 'MATERIALIZED' ([CREATE] MATERI
ALIZED...)">

Answer 1

Cassandra 中的物化视图解决了不必维护额外表以通过不同分区键进行查询的用例。但有以下限制

• 将物化视图中的所有基表主键用作主键。
• （可选）将基表中的一个非 PRIMARY KEY 列添加到 物化视图的主键。
• 不支持将静态列作为主键。

更多文档参考here。

因此，在您添加物化视图的情况下，正确的语法应该是

CREATE MATERIALIZED VIEW orders_by_date AS 
    SELECT  id, 
            order_number, 
            country, 
            store_number, 
            supplier_number, 
            flow_type, 
            planned_delivery_date, 
            locked
            FROM all_orders
            WHERE planned_delivery_date IS NOT NULL AND order_number IS NOT NULL AND store_number IS NOT NULL AND supplier_number IS NOT NULL
            PRIMARY KEY ( planned_delivery_date, store_number, supplier_number, order_number );

这里的planned_delivery_date 是分区键，行按store_number、supplier_number、order_number 排序（本质上是集群列）。所以这里没有强制要求添加“CLUSTERING ORDER BY”子句。