如何在 Perl 数组中搜索匹配的字符串？

Question

在 Perl 中通过字符串数组搜索匹配字符串的最聪明的方法是什么？

一个警告，我希望搜索不区分大小写

所以"aAa" 将在("aaa","bbb") 中

Answer 1

对于布尔匹配结果或出现次数，您可以使用：

use 5.014; use strict; use warnings;
my @foo=('hello', 'world', 'foo', 'bar', 'hello world', 'HeLlo');
my $patterns=join(',',@foo);
for my $str (qw(quux world hello hEllO)) {
    my $count=map {m/^$str$/i} @foo;
    if ($count) {
        print "I found '$str' $count time(s) in '$patterns'\n";
    } else {
        print "I could not find '$str' in the pattern list\n"
    };
}

输出：

I could not find 'quux' in the pattern list
I found 'world' 1 time(s) in 'hello,world,foo,bar,hello world,HeLlo'
I found 'hello' 2 time(s) in 'hello,world,foo,bar,hello world,HeLlo'
I found 'hEllO' 2 time(s) in 'hello,world,foo,bar,hello world,HeLlo'

不需要使用模块。
当然，它不像上面的一些代码那样“可扩展”和通用。
我将其用于交互式用户答案，以匹配一组预定义的不区分大小写的答案。

Answer 2

这取决于您希望搜索做什么：

• 如果要查找所有匹配项，请使用内置的grep：

  my @matches = grep { /pattern/ } @list_of_strings;
  

• 如果您想找到第一个匹配项，请在List::Util 中使用first：

  use List::Util 'first';  
  my $match = first { /pattern/ } @list_of_strings;
  

• 如果要查找所有匹配项的计数，请在List::MoreUtils 中使用true：

  use List::MoreUtils 'true';
  my $count = true { /pattern/ } @list_of_strings;
  

• 如果您想知道第一个匹配的索引，请在List::MoreUtils 中使用first_index：

  use List::MoreUtils 'first_index'; 
  my $index = first_index { /pattern/ } @list_of_strings;
  

• 如果您只想知道是否有匹配项，但您不关心它是哪个元素或它的值，请在List::Util 中使用any：

  use List::Util 1.33 'any';
  my $match_found = any { /pattern/ } @list_of_strings;
  

所有这些示例的核心都是类似的事情，但它们的实现已经过高度优化，速度很快，并且比你自己用grep、map 或 @ 编写的任何纯 perl 实现都要快987654328@.

---

请注意，执行循环的算法与执行单个匹配是一个单独的问题。要不区分大小写地匹配字符串，您可以简单地在模式中使用i 标志：/pattern/i。如果您以前没有阅读过perldoc perlre，那么您绝对应该阅读。

Answer 3

#!/usr/bin/env perl

use strict;
use warnings;
use Data::Dumper;

my @bar = qw(aaa bbb);
my @foo = grep {/aAa/i} @bar;

print Dumper \@foo;

Answer 4

Perl 字符串匹配也可用于简单的是/否。

my @foo=("hello", "world", "foo", "bar");

if ("@foo" =~ /\bhello\b/){
    print "found";
}
else{
    print "not found";
}

Answer 5

Perl 5.10+ 包含“智能匹配”运算符~~，如果某个元素包含在数组或散列中，则返回 true，否则返回 false（参见 perlfaq4）：

好消息是它还支持正则表达式，这意味着您可以轻松处理不区分大小写的要求：

use strict;
use warnings;
use 5.010;

my @array  = qw/aaa bbb/;
my $wanted = 'aAa';

say "'$wanted' matches!" if /$wanted/i ~~ @array;   # Prints "'aAa' matches!"

Answer 6

如果您要对数组进行多次 搜索，AND 匹配总是被定义为字符串等价，那么您可以规范化您的数据并使用哈希。 p>

my @strings = qw( aAa Bbb cCC DDD eee );

my %string_lut;

# Init via slice:
@string_lut{ map uc, @strings } = ();

# or use a for loop:
#    for my $string ( @strings ) {
#        $string_lut{ uc($string) } = undef;
#    }


#Look for a string:

my $search = 'AAa';

print "'$string' ", 
    ( exists $string_lut{ uc $string ? "IS" : "is NOT" ),
    " in the array\n";

让我强调一下，如果您打算在数组上进行多次查找，那么进行哈希查找是很好的。此外，它仅在匹配意味着 $foo eq $bar 或可以通过规范化满足的其他要求（如不区分大小写）时才有效。

Answer 7

我猜

@foo = ("aAa", "bbb");
@bar = grep(/^aaa/i, @foo);
print join ",",@bar;

会成功的。