cmd批量重命名子文件夹/文件答案

【问题标题】：cmd batch rename subfolders/filescmd批量重命名子文件夹/文件
【发布时间】：2012-05-04 19:50:03
【问题描述】：

如何批量重命名文件夹 A 中的文件，该文件夹包含具有此格式名称 filename_ex.doc 的子文件夹和文件，并使它们看起来像 filename.doc？

我一直在尝试这样做一段时间，但这是一次史诗般的失败。请帮忙。

【问题讨论】：

@MartinJames 每当我尝试批量“编程”时，我都失败了，以至于我永远不会发布我在这些步骤中开发的任何代码 sn-ps ;-)
我试过 FOR /F ， FOR /D 所有这些东西，并从这里阅读文档：link。到目前为止还没有像样的结果... :( 我真的很讨厌 Windows 批处理编程。
@MartinJames：也从命令行尝试过：for "tokens=1-3 delims=_." %a ('dir *_ex.ext') do echo %a_%b.%c ...如果我的 PATH 包含文件夹/子文件夹或其他包含字符的文件：“。”和“_”

标签： windows batch-file cmd

【解决方案1】：

我想您也想重命名子文件夹中的文件，这是您对 Martin James 的第二条评论中的方向有问题的地方。我猜你用 DIR /S 选项尝试了该代码。但你是如此接近 :-) 你只需要使用 2 个循环！

编辑 - 修复代码一旦输出看起来正确，删除 ECHO 以使其正常工作。

@echo off
for /r %%D in (.) do (
  pushd "%%~fD"
  for /f "tokens=1-3 delims=_." %%A in ('dir /b *_ex.ext 2^>nul') do echo ren "%%A_%%B.%%C" "%%A.%%C"
  popd
)

只要每个文件名不包含_ 或. 以外的_ex.ext 中的名称，上述方法将有效。路径中的字符应该没有问题，只是文件名是一个问题。

这是一个更强大的解决方案，应该适用于任何文件名（unicode 名称除外）。它也明显更快。它使用子字符串操作，您必须知道要从名称中删除的字符数。在您的示例中，它是 3 个字符。再次，一旦结果命令看起来正确，就删除 ECHO。

@echo off
setlocal disableDelayedExpansion
for /f "delims=" %%F in ('dir /b /s *_ex.ext') do (
  set "old=%%F"
  set "new=%%~nF"
  setlocal enableDelayedExpansion
  echo ren "!old!" "!new:~0,-3!.ext"
  endlocal
)

【讨论】：

如果您在子文件夹和文件名中包含下划线，这会起作用吗？
我已经测试过了。它不起作用，但我会检查有什么问题。谢谢
@Alex - 我会说它没有用。我修复了 2 个错误，并添加了一个更强大、更快的替代方案。