如何在 Groovy 中使 textarea 宽度适合父级

Question

布局最初看起来不错，但是当窗口重新调整大小时，文本区域没有正确调整大小。

知道怎么解决吗？

谢谢！

import java.awt.BorderLayout
import javax.swing.BorderFactory
import java.awt.GridLayout
import groovy.swing.SwingBuilder

swing = new SwingBuilder()
frame = swing.frame(title:'Test', location:[200,200], size:[300,216]) {
    panel(layout: new BorderLayout()){
        scrollPane(constraints: BorderLayout.NORTH){
            table {
                def people = [
                             ['name':'Johan', 'location':'Olso'],
                             ['name':'John', 'location':'London'], 
                             ['name':'Jose', 'location':'Madrid'], 
                             ['name':'Jos', 'location':'Amsterdam']
                            ]

                tableModel( id:'model', list: people) { m ->
                    propertyColumn(header: 'Name', propertyName: 'name')
                    propertyColumn(header: 'Location', propertyName: 'location')
                }
            }
        }
    }

    panel(constraints: BorderLayout.SOUTH){
        scrollPane(constraints: BorderLayout.CENTER){
            textArea(id:'TextArea', lineWrap:true,wrapStyleWord:true, columns:35, rows:4,editable:true)
        }  
    }             
}
frame.show()

初步没问题

调整大小后不行

Answer 1

问题的主要来源是JPanel 的默认布局管理器是FlowLayout，而不是BorderLayout，并且您正在使用BorderLayout 约束。

panel(constraints: BorderLayout.CENTER, layout: new BorderLayout()) {
    scrollPane(constraints: BorderLayout.CENTER){
        textArea(id:'TextArea', lineWrap:true,wrapStyleWord:true, columns:35, rows:4,editable:true)
    }  
}

将文本字段和包含面板扩展到所有可用空间。 （更改是使用面板的 CENTER 位置，并为其设置布局管理器）。

我还把桌子放在了 NORTH 位置（因为我把下面板移到了 CENTER）：

panel(constraints: BorderLayout.NORTH, layout: new BorderLayout()) {
...

您可能希望不这样做，但由于选择取决于您的确切偏好，我不知道什么是适合您的。

你也应该使用

frame.pack()
frame.show()

而不是显式设置帧大小。这使框架大小适合所包含组件的首选大小。