Mac Underscan 调整编码问题 - AppleScript

Question

我尝试使用 AppleScript 调整显示 > underscan 从 Off 到 2nd level 的 underscan 设置栏。因为我的 Mac Mini 会在我每次打开电视或从睡眠中醒来时自动关闭欠扫描设置。

我参考了网上的一些编码，确实做了打开“设置”和“显示”选项卡的代码，但我不知道下一步。有谁知道其他编码应该是什么？

我的代码：

activate application "System Preferences"
tell application "System Events"
    tell process "System Preferences"
        click button "Displays" of scroll area 1 of window "System Preferences"
        delay 0.5
        
        tell tab group 1 of window "42PFD5519/30"
            click radio button "Default for Display"
            
            -- What code should i use?
            
        end tell
    end tell
    delay 0.5
    quit application "System Preferences"
end tell

和参考照片

Answer 1

我没有像你这样的设置来测试，但是，我是这样编码的：

示例 AppleScript 代码：

--  # Check to see if System Preferences is 
--  # running and if yes, then close it.
--  # 
--  # This is done so the script will not fail 
--  # if it is running and a modal sheet is 
--  # showing, hence the use of 'killall' 
--  # as 'quit' fails when done so, if it is.
--  #
--  # This is also done to allow default behaviors
--  # to be predictable from a clean occurrence.

if running of application "System Preferences" then
    try
        tell application "System Preferences" to quit
    on error
        do shell script "killall 'System Preferences'"
    end try
    delay 0.1
end if

--  # Make sure System Preferences is not running before
--  # opening it again. Otherwise there can be an issue
--  # when trying to reopen it while it's actually closing.

repeat while running of application "System Preferences" is true
    delay 0.1
end repeat

--  # Open System Preferences to the 
--  # Display tab of the Displays pane. 

tell application "System Preferences" to ¬
    reveal anchor "displaysDisplayTab" of ¬
        pane id "com.apple.preference.displays"

tell application "System Events"
    tell application process "System Preferences"
        
        --  # Wait for the UI to be available.

        set i to 0
        repeat until exists ¬
            radio button 1 of ¬
            tab group of window 1
            delay 0.1
            set i to i + 1
            if i ≥ 30 then return
        end repeat

        --  # Click the target radio button
        --  # and adjust the target slider.
        
        tell tab group 1 of window 1
            click radio button "Default for display"
            set value of slider 1 to 0.2
        end tell
        
    end tell
end tell

delay 0.2

tell application "System Preferences" to quit

注意事项：

通常，slider 的 值 介于 0.0 和 1.0 之间，所以我使用了 0.2，所以它应该会在你想要的位置结束，但是，调整 value 视需要而定。

示例 AppleScript 代码，如上所示，在 ma​​cOS Catalina 下的 Script Editor 中进行了测试 将 系统偏好设置 中的 语言和地区 设置设置为 英语（美国）- 主要 并且为我工作没有问题 ¹.

• ¹ _{假设 系统偏好设置 > 安全和隐私 > 隐私中的必要和适当的设置已设置/根据需要解决。}

---

_{注意：示例 AppleScript 代码就是这样，没有任何包含的错误处理 em> 不包含任何适当的附加错误处理。用户有责任根据需要或需要添加任何错误处理。查看AppleScript Language Guide 中的try statement 和error statement。另请参阅Working with Errors。此外，在适当的情况下，可能需要在事件之间使用delay 命令，例如delay 0.5，延迟的值设置得当。}