Haskell：我如何反转树的孩子递归

Question

我正在尝试在 haskell 中反转 Tree 的孩子。树看起来像这样：

data Tree v e = Node v [(e,Tree v e)]  

目前我使用这两个功能：

rev :: Tree v e -> Tree v e
rev (Node v []) = Node v []
rev (Node v xs) =
  let xs' = (rev'(snd (unzip xs)))
  in Node v (zip (fst (unzip xs)) (map rev xs'))


rev' :: [Tree v e] -> [Tree v e]
rev' [] = []
rev' (x:xs) = (rev' xs) ++ [x]  

我什至不确定这是否 100% 有效。有没有办法只在一个函数中递归？我觉得我的方式效率低下。我试图编写一个如下所示的函数：

revRec :: Tree v e -> Tree v e
revRec (Node v [])     = Node v []
revRec (Node v (x:xs)) = Node v (revRec xs ++ [x]) 

显然我不能用xs 调用revRec，因为xs 是一个列表。即使我觉得它不应该那么难，我也无法解决这个问题。

Answer 1

Zeroth，清理你的代码。你不需要那么多括号，你应该避免重复计算。 fst 和 snd 是同一件事的两倍？嗯。更好地使用模式匹配：

rev :: Tree v e -> Tree v e
rev (Node v xs)
  = let (es, cs) = unzip xs
        xs' = rev' cs
    in Node v $ zip es (map rev xs')

rev' :: [Tree v e] -> [Tree v e]
rev' [] = []
rev' (x:xs) = rev' xs ++ [x]  

首先请注意，rev' 根本不特定于树列表！它只是^{_{一个低效的实现}}标准reverse函数，它适用于任何列表。

第二，这个解压/压缩有点笨拙。您确定这实际上是您想要的行为吗：现在您只是反转子列表，但 elements 的顺序保持不变。如果没有，那么你最好用一张反向和一张地图来做这一切：

rev :: Tree v e -> Tree v e
rev (Node v xs) = Node v . reverse $ map (\(e,c) -> (e, rev c)) xs

或者，甚至更好，

import Control.Arrow

rev (Node v xs) = Node v . reverse $ map (second rev) xs