用来自另一个文件的多行替换文件中的多行

Question

我可以在几个命令中搜索和替换文件中的多行吗？

我正在尝试用来自dhcp_secondary 的唯一故障转移块替换来自dhcp_primary 的3 个故障转移块，在dhcp_primary 内。

我的目标是将 dhcpd.conf 从主 dhcp 复制到辅助 dhcp（更多信息在这里：http://www.madboa.com/geek/dhcp-failover/）。故障转移只有在配置相同的情况下才能工作，当然除了故障转移块；如您所见，是该网站的示例。 所以我想复制这个文件，但保留辅助节点的故障转移信息。

例如dhcp_primary:

// some lines above
failover peer "A" {
...
}
failover peer "B" {
...
}
failover peer "C" {
...
}
// some lines below

例如dhcp_secondary:

// some different lines above
failover peer "D" {
...
}
// some different lines below

预期的输出必须是：

// some lines above
failover peer "D" {
...
}
// some lines below

我已经可以提取故障转移块了：

awk '/^failover/,/^}$/' dhcp_a

awk '/^failover/,/^}$/' dhcp_b

但我不知道如何继续。

提前致谢。

编辑：我的目标的更多细节。

Answer 1

你可以试试：

awk -f a.awk dhcp_b dhcp_a

a.awk 在哪里：

/^failover/,/^}$/{
    if (NR==FNR) {
        blk=blk $0 RS
        next
    }
    if (++i==1) {
        printf "%s",blk
    }
    next
}
NR!=FNR{  print }

Answer 2

这可能对你有用（GNU sed）：

sed -n '/^failover peer/,/^}/p' dhcp_b | 
sed -e '/^failover peer/,/^}/!b;r /dev/stdin' -e 'd' dhcp_a

Answer 3

如果文件只是这种结构和内容类型

NewFile=./FileName

head -1 dhcp_a > ${NewFile}
sed -n '1!{$!p;};}' dhcp_b >> ${NewFile}
tail -1 dhcp_a >> ${NewFile}

只取 dhcp_a 的头部和尾部，并阻止 dhcp_b 的内容

如果文件更大（周围的内容），则使用 /failover/,/}/ 之类的东西作为 sed 中的块分隔符，但这取决于实际内容

Answer 4

$ cat tst.awk
/^failover/ { inRec  = 1 }

{
    if (NR == FNR) {
        if (inRec) {
            rec = rec $0 ORS
        }
    }
    else {
        if (inRec) {
            printf "%s", rec
            rec = ""
        }
        else {
            print
        }
    }
}

/^}/ { inRec = 0 }

$ awk -f tst.awk secondary primary
// some lines above
failover peer "D" {
...
}
// some lines below