使用 sed 插入一行

Question

我有一个类似的ini文件：

...
abc = 123
def = 456
...

我想将其更改为：

...
abc = 123
xyz = 987
def = 456
...

我没有成功地尝试过这个： sed -i 's/abc = 123\ndef = 456/abc = 123\nxyz = 987\ndef = 456/g' myfile.ini 如何修复我对 sed 的呼叫以使其正常工作？

Answer 1

使用 sed 的另一种方法：

sed '/abc = 123/N;s/\ndef = 456/\nxyz = 987&/' myfile.ini

Answer 2

sed '
    /^def / {     # if this line matches the  2nd pattern
        x         # swap this line and the hold space
        /^abc / { # if this line matches the 1st pattern
                  # insert the new line
            i\
xyz = 987
        }
        x         # re-swap this line and the hold space
    }
    h             # put this line into the hold space
' file.ini

Answer 3

Sed 自然只查看一行，因此它不会找到您想要的'\n' 字符。最简单的解决方案是将所有 '\n' 替换为另一个临时字符，例如 '\f'（换页符）。

这是我一直在使用的骇人听闻的方法。 （为清楚起见分开）

cat myfile.ini |
tr '\n' '\f' |
sed -e "s/abc = 123\fdef = 456/abc = 123\fxyz = 987\fdef = 456/g" |
tr '\f' '\n'

'\f' 是换页符。如果您使用的是 MacOS，则需要将 sed 语句中的所有 '\f' 替换为 $(printf '\f')。

注意：我还建议使用 sed 分组语法以使您的模式更易于阅读。

很难用 sed 进行多行编辑。您应该查看 perl 以获得更复杂的编辑。

Answer 4

这是一种在模式后追加一行的可移植方式：

<myfile.ini sed '/abc = 123/a\
xyz = 789
'

输出：

abc = 123
xyz = 789
def = 456