perl 中的正则表达式，它使用组从文件路径中提取信息

Question

所以我需要采用这种格式：2015-08-15_15-41-32_44100_logo.txt 并使用这两段代码从中提取日期、时间和频率。现在它的形式是<date>_<time>_<frequency>_logo.txt.Below 是我尝试使它成为一个正则表达式，但我知道我遗漏了一些东西。我如何在 perl 中使用组来做到这一点？ 下面的代码在目录中搜索遵循该模式的每个文件路径，并在列表中返回这些文件。我需要帮助的是正则表达式本身。我需要能够获得频率。

$pattern =qr/^(\d+)-(\d+)-(\d+)_(\d+)-(\d+)-(\d+)_44100_(\w+).(\w+)$/;
@listFiles = grep_files($bee_music_dir,$pattern);
print join(",",@listFiles);

sub grep_files {
    my ($dir, $pat) = @_;
    opendir(my $dir_handle, $dir) or die $!;
    my @files = grep { $_ =~ /$pat/ } readdir($dir_handle);
    closedir($dir_handle);
    return \@files;
}

Answer 1

perl 中的正则表达式组是这样使用的：

my ($a, $b, $c) = $somestring=~ /(\d+)-(\d+)-(\d+)/;

这里，($a, $b, $c) 列表中的每个变量都被分配了匹配组的值，这些匹配组也可用作 $1、$2 和 $3。所以上面一行相当于：

$somestring =~ /(\d+)-(\d+)-(\d+)/;
my ($a, $b, $c) = ($1, $2, $3);

（你甚至可以使用my $a = $1; my $b = $2; my $c = $3）。

如果你想声明一个$pattern 变量，你应该这样做：

my $pattern = qr/(\d+)-(\d+)-(\d+)_(\d+)-(\d+)-(\d+)_(\d+)_(\w+).(\w+)/;

其中qr 是quote-regexp 运算符，预编译正则表达式以进行优化。您不应该在这里使用=~ 运算符，因为它会将正则表达式应用于$pattern，而不是将$pattern 定义为该正则表达式。 以这种方式定义模式可以让您只需

$stringtomatch =~ $pattern;

（但=~ /$pattern/ 也可以）。

匹配格式为2015-08-15_15-41-32_44100_logo.txt 或<date>_<time>_<frequency>_logo.txt 的文件的正则表达式如下所示：

/^(\d\d\d\d)-(\d\d)-(\d\d)_(\d\d)-(\d\d)-(\d\d)-(\d+)_logo\.txt$/

您可以使用\d+，但它不一定与日期匹配。此外，正则表达式中的. 表示“任何字符”，所以如果你真的是指.，你应该转义它：\.。

这是您的子部分的更详细版本，说明了对组的访问：

my @files = ();
while ( my $file = readdir($dir_handle) ) {
   if ( my ($year,$month,$day,$hour,$minute,$second,$freq) = $file =~ $pattern ) {
       # do something with $freq
       push @files, $file;
   }
}

如果您所追求的只是频率列表，则只需对所需字段进行“分组”即可：

my $pattern = qr/^\d+-\d+-\d+_\d+-\d+-\d+_(\d+)_logo\.txt$/;

Answer 2

你很接近，只是一些变化。这是脚本和测试运行：

$ cat freq.pl
#!/usr/bin/perl --

use strict;
use warnings;

my $pattern = qr/^(\d+)-(\d+)-(\d+)_(\d+)-(\d+)-(\d+)_(\d+)_(\w+).(\w+)$/;

sub grep_files {
    my ($dir, $pat) = @_;
    opendir(my $dir_handle, $dir) or die $!;
    my @files = grep { $_ =~ /$pat/ } readdir($dir_handle);
    s/$pat/$7/ foreach @files;
    closedir($dir_handle);
    \@files;
}

print join("\n", @{grep_files '.', $pattern}), "\n";
$ ls
2015-08-15_15-41-32_44100_logo.txt  freq.pl
2015-08-25_25-41-32_48000_logo.txt
$ ./freq.pl
44100
48000

freq.pl 从当前目录中的文件名中提取频率。它基于您的，但有一些关键区别：

• 您正在将模式与未定义的变量进行匹配。您真的想将模式存储在变量中。我还在开头和结尾锚定了模式，所以在（在这种情况下显然不太可能发生的事件）你有其他文件在开头或结尾有东西，它不会偶然匹配那些。您还缺少行尾的分号。
• 您选择了与模式匹配的文件，但没有提取频率。 s/$pat/$7/ foreach @files; 循环遍历与模式匹配的所有文件，并仅用第 7 组（即频率）替换所有内容。您还可以使用map 而不是grep，一步选择文件并提取频率。
• 我添加了最后一行进行测试。
• 虽然不直接相关，但请始终在脚本顶部使用 use strict 和 use warnings。 use strict 会产生一些可疑的构造错误，use warnings 会警告脚本可能存在的一些问题。

ls 显示当前目录中的示例文件，freq.pl 运行显示输出的脚本。