在文件中将时间戳转换为纪元

Question

我有一个 制表符 分隔文件，第三个字段中有时间戳，我需要在 bash 中更改为纪元。

示例输入：

xyz@gmail.com   SALE    2017-04-26 12:47:27     30.0    1       201704
xyz@gmail.com   SALE    2017-04-26 12:46:15     20.0    2       201704
xyz@gmail.com   PAYBACK 2017-04-18 08:02:31     95.0    3       201704
xyz@gmail.com   SEND    2017-04-18 08:00:37     4800.0  4       201704
xyz@gmail.com   SEND    2017-04-17 14:59:34     4900.0  5       201704

我尝试了awk 'BEGIN {IFS="\t"} {$3=system("date -d \""$3"\" '+%s'");print}' file，它给出了最接近的结果，但它在一行中显示纪元，然后在新行中再次显示记录，时间戳值为零。我需要在一条记录中全部替换第三个字段。

Answer 1

使用 GNU awk：

$ cat tst.awk
BEGIN { FS=OFS="\t" }
{
    $3 = mktime(gensub(/[-:]/," ","g",$3))
    print
}

$ awk -f tst.awk file
xyz@gmail.com   SALE    1493228847      30.0    1       201704
xyz@gmail.com   SALE    1493228775      20.0    2       201704
xyz@gmail.com   PAYBACK 1492520551      95.0    3       201704
xyz@gmail.com   SEND    1492520437      4800.0  4       201704
xyz@gmail.com   SEND    1492459174      4900.0  5       201704

与其他 awks：

$ cat tst.awk
BEGIN { FS=OFS="\t" }
{
    cmd = "date -d \"" $3 "\" \047+%s\047"
    if ( (cmd | getline line) > 0 ) {
        $3 = line
    }
    close(cmd)
    print
}

$ awk -f tst.awk file
xyz@gmail.com   SALE    1493228847      30.0    1       201704
xyz@gmail.com   SALE    1493228775      20.0    2       201704
xyz@gmail.com   PAYBACK 1492520551      95.0    3       201704
xyz@gmail.com   SEND    1492520437      4800.0  4       201704
xyz@gmail.com   SEND    1492459174      4900.0  5       201704

写你的脚本 - 没有名为 IFS 的内置 awk 变量，system 返回最后一个命令运行的退出状态，而不是标准输出，并且你不能在任何 '-delimited 中包含 's从 shell 调用的脚本。

想要“就地”进行，没有 UNIX 编辑器真的可以就地编辑，但在 GNU awk 中，您可以使用 -i inplace 来避免自己指定 tmp 文件名。但是，对于任何 UNIX 命令，您只需执行 cmd file > tmp && mv tmp file。

请注意，这是 getline 的极少数适当用途之一 - 请参阅 http://awk.freeshell.org/AllAboutGetline 了解其他有效用途，最重要的是，除非绝对必要，否则不要使用它的注意事项和理由。