sed 删除字符串直到下一次出现

Question

想象一下，我有一些聊天记录协议。它可能看起来像这样：

MSG sender|reciever2: Hello its meCRLF
MSG bob|anna: Hello annaCRLF
MSG bob|anna: How are youCRLF
MSG anna|bob: Im fine, you?CRLF
MSG bob|anna: Same, wanna hang out some time?CRLF
MSG anna|bob: YesCRLF
MSG bob|peter: hey im asking anna to hang out lolCRLF
MSG anna|bob: for sureCRLF
MSG anna|bob: maybe in a few weeks?CRLF

我只想获得 Anna 和 Bob 之间的聊天，但只想知道发件人的姓名一次，直到另一个聊天伙伴开始。

我已经归档的是这个 sed 脚本。

s/^MSG\s+(anna|bob)\|(anna|bob)\:\s{1}(.+)CRLF$/\1: "\3"/g
t end

/^.*/d

:end

这会创建：

bob: "Hello anna"
bob: "How are you"
anna: "Im fine, you?"
bob: "Same, wanna hang out some time?"
anna: "Yes"
anna: "for sure"
anna: "maybe in a few weeks?"

但我想要类似的东西：

bob: 
  Hello anna
  How are you
anna
  Im fine, you?
bob: 
  Same, wanna hang out some time?
anna: 
  Yes
  for sure
  maybe in a few weeks?

那么，如何在一个鲍勃之后删除所有鲍勃，直到下一个安娜来？ 请注意，这是我拥有可以使用 sed 的一些东西。这必须在带有 sed (GNU sed) 4.7 Packaged by Debian 的 Ubuntu Linux 系统上运行

Answer 1

这使用 POSIX sed 语法。

sed '
/^MSG \(anna\)|bob:/!{
  /^MSG \(bob\)|anna:/!d
}
s//\1:\
 /;s/CRLF$//;t t
:t
H;x;s/^\([^:]*:\n\).*\1//;t
g' file

它将当前记录附加到保持空间中的前一条记录，交换它们，删除重复名称（连同前一条记录），或者将模式空间恢复为原始当前记录。

这是一个更高效的版本：

sed '
t
/^MSG \(anna\)|bob:/!{
  /^MSG \(bob\)|anna:/!d
}
s//\1:\
 /;s/CRLF$//
H;s/:.*/:/
x;s/^\([^:]*:\n\)\1//p;D' file

这避免了在重复检测正则表达式中使用.*，方法是使用保持空间来存储以前的名称而不是整个以前的记录。

Answer 2

这可能对你有用（GNU sed）：

sed -E '/^MSG ((anna)\|bob|(bob)\|anna): (.*)CRLF/{s//\2\3:\4/;H};$!d
       x;s/(\n.*:).*(\1.*)*/\1\n&/mg;s/\n+.*:(\S)/\n  \1/mg;s/.//' file

开启扩展正则表达式-E。

在保留空间中收集anna 和bob 对话。

在文件交换到保留空间的末尾，将以下对话行的名称添加到前面，删除不需要的名称，并为添加的名称在每行对话中缩进空格。

最后删除第一个换行符。

---

另一种解决方案（类似于 KamilCuk）：

sed -E '/^MSG ((anna)\|bob|(bob)\|anna): (.*)CRLF/!d;s//\2\3:\4/;G
        /^([^:]*:)(.*)\n\1$/{s//  \2/p;d};h;s/:.*/:/p;x;s/[^:]*:/  /;P;d' file

Answer 3

以下脚本：

cat <<EOF |
MSG sender|reciever2: Hello its meCRLF
MSG bob|anna: Hello annaCRLF
MSG bob|anna: How are youCRLF
MSG anna|bob: Im fine, you?CRLF
MSG bob|anna: Same, wanna hang out some time?CRLF
MSG anna|bob: YesCRLF
MSG bob|peter: hey im asking anna to hang out lolCRLF
MSG anna|bob: for sureCRLF
MSG anna|bob: maybe in a few weeks?CRLF
EOF
sed '
  # preprocess - remove uninterested parts
  /MSG \(\(anna\)|bob\|\(bob\)|anna\): \(.*\)CRLF/!d
  s//\2\3:\4/

  # Check if are doing it again with same name.
  G   # Grab the previous name from hold space.
  /^\([^:]*\):\(.*\)\n\1$/{   # The names match?
    s//  \2/p                 # Print only the message.
    d
  }

  h    # Put the whole line into hold space. For later.
  s/^\([^:]*\):\([^\n]*\).*/\1/   # Extract only name from the line.
  x    # Put the name in hold space, and grab the full line from hold space.
  s//\1:\n  \2/     # Print the name with the message.
'

输出：

bob:
  Hello anna
  How are you
anna:
  Im fine, you?
bob:
  Same, wanna hang out some time?
anna:
  Yes
  for sure
  maybe in a few weeks?