如何在 TIdMultiPartFormDataStream 中包含文件以与 Indy IdHTTP1.Post 一起使用？

Question

使用 Indy 的 idHTTP.post 发送一个或多个任何类型的文件以及其他参数需要使用的正确代码是什么？ （使用 Delphi 2009 和 Indy 10）

有问题的帖子调用了商业公司 API (ElasticEmail) 中的一个函数，该函数向其中一个参数中保存的收件人发送电子邮件。 （我正在调用的函数的文档链接是here. 我有来自公司here 的 C# 和其他语言的示例代码，我尝试在下面的 Delphi 代码中复制该代码。

如果，在过程 btnSendbyElastic 中，我注释掉 Filenames.add(Afilename); 行，以便函数 Upload 不会尝试附加文件，那么当 API 成功发送电子邮件时，似乎进行了正确的调用。 但是，如果我保留该行，以便函数 UpLoad 中的行

MimeStr := GetMIMETypeFromFile(filenames[i]);
FormData.Addfile('file'+inttostr(i), filenames[i],MIMEStr); 

做被执行，然后没有电子邮件被发送并且来自服务器的响应是

{"success":false,"error":"其中一个文件的文件名中包含无效字符。"}

（文件 Afilename 确实存在于该位置，我已尝试使用单反斜杠和双反斜杠）

阅读有关此主题的其他 SO 帖子，我还尝试将 Function UpLoad 中的文件处理循环替换为以下循环

for i := 0 to filenames.Count - 1 do
    begin
    MimeStr := GetMIMETypeFromFile(filenames[i]); 
    FormData.AddFile('file'+inttostr(i), filenames[i],MIMEStr);
    AttachmentContent  := TFileStream.Create(filenames[i],fmOpenRead);
    try
        FormData.AddFormField(AttachmentContent.ToString,filenames[i]);
    finally
        AttachmentContent.free;
    end;
end; 

这一次，即使使用Filenames.add(Afilename); 中指定的文件名，电子邮件也可以正确发送，但收件人看不到附件。

在许多其他人中，我已经阅读了这些可能重复的 SO 问题

Http Post with indy

Post a file through https using indy / delphi components

posting a file as part of a form

Nodejs POST request multipart/form-data

特别是

Using the Indy TidHttp component to send email file attachments through sendgrid

（这几乎正是我想要做的）但我仍然看不到我在代码中做错了什么以及我需要做些什么来纠正它。

这是我正在使用的代码（UPPER_CASE 标识符是在别处定义的常量）

PS 我在英国，很抱歉延迟回复美国 cmets/answers

function TForm1.Upload(url: string; params, filenames: Tstringlist): string;
var
 FormData : TIdMultiPartFormDataStream;
 MIMEStr, ResponseText : string;
 i : integer;
begin
  try
  FormData := TIdMultiPartFormDataStream.Create;
  for i := 0 to params.Count - 1 do
        FormData.AddFormField(params.Names[i],params.values[params.Names[i]]);
   for i := 0 to filenames.Count - 1 do
     begin
     MimeStr := GetMIMETypeFromFile(filenames[i]); 
     FormData.Addfile(filenames[i], filenames[i],MIMEStr);
     end;
  ResponseText :=IdHTTP1.Post(url, FormData);
  Memo1.Text := ResponseText; //debug
  finally
  FormData.free;
  end;
end;

procedure TForm1.btnSendbyElastic(Sender: TObject);
var
Params, Filenames : Tstringlist;
url, Afilename : string;
begin
Afilename := 'C:\\Users\\Admin\\Documents\\arrival and departure small.pdf';
Params := Tstringlist.Create;
Filenames  := Tstringlist.Create;
try
  Params.add('apikey=' + ELASTIC_MAIL_API_KEY) ;
  Params.add('from=' + ELASTIC_EMAIL_FROM_EMAIL) ;
  Params.add('fromname=' + ELASTIC_EMAIL_FROM_NAME) ;
  Params.add('Subject=' + 'The Subject') ;
  Params.add('bodyHtml=' + '<h1>Html Body</h1>') ;
  Params.add('bodyText=' + 'Text Body') ;
  Params.add('to=' + THE_RECIPIENT_ADDRESS) ;
  Filenames.add(Afilename); //*** comment out this line and an email is sent correctly
  url := ELASTIC_EMAIL_EMAIL_SEND  ;
  Upload (url , params, filenames );
finally
  Params.free;
  Filenames.free;
end;

函数GetMIMETypeFromFile 定义在 Indy 单元 idGlobalProtocols 中。不是我写的，就是叫的。但我已经按要求在这里转载了

function GetMIMETypeFromFile(const AFile: TIdFileName): string;
var
  MIMEMap: TIdMIMETable;
begin
  MIMEMap := TIdMimeTable.Create(True);
  try
    Result := MIMEMap.GetFileMIMEType(AFile);
  finally
    MIMEMap.Free;
  end;
end;

Answer 1

我发现您的代码存在一些问题。

您在文件路径中错误地转义了 \ 字符。这在 C 和 C++ 等语言中是必需的，但在 Delphi 中根本不需要，所以去掉它。

改变这个：

Afilename := 'C:\\Users\\Admin\\Documents\\arrival and departure small.pdf';

到这里：

Afilename := 'C:\Users\Admin\Documents\arrival and departure small.pdf';

我看到的下一个问题是将文件附件字段添加到TIdMultipartFormDataStream 时没有正确命名它们。

调用AddFile() 时，您将完整的文件路径原样传递给AFieldName 参数，而不是像Elastic 的示例中那样使用file0、file1 等名称。

改变这个：

FormData.Addfile(filenames[i], filenames[i],MIMEStr);

至此¹：

FormData.AddFile('file'+IntToStr(i), filenames[i], MIMEStr);

^{1：仅供参考，如果您没有为AContentType 参数提供字符串，例如FormData.AddFile('file'+IntToStr(i), filenames[i]);}

当您尝试使用AddFormField() 而不是AddFile() 添加附件时，您犯了类似的错误。您将每个文件的实际数据内容用于AFieldName 参数，而不是使用AFieldValue 参数的内容。

在这种情况下，改变这个：

FormData.AddFormField(AttachmentContent.ToString,filenames[i]);

到这里：

FormData.AddFormField('file'+IntToStr(i), AttachmentContent.ToString, '', MIMEStr, filenames[i]);

或者，由于您自己打开 TFileStream 对象，您可以使用重载的 AddFormField() 方法，该方法将 TStream 作为输入（请确保在完成使用之前不要释放 TStream 对象TIdMultipartFormDataStream!):

AttachmentContent := TFileStream.Create(filenames[i], fmOpenRead);
FormData.AddFormField('file'+IntToStr(i), MIMEStr, '', AttachmentContent, filenames[i]);

话虽如此，请尝试更多类似的东西：

function TForm1.Upload(url: string; params, filenames: TStrings): string;
var
 FormData : TIdMultiPartFormDataStream;
 ResponseText : string;
 i : integer;
begin
  FormData := TIdMultiPartFormDataStream.Create;
  try
    for i := 0 to params.Count - 1 do
      FormData.AddFormField(params.Names[i], params.ValueFromIndex[i]);

    for i := 0 to filenames.Count - 1 do
      FormData.AddFile('file'+IntToStr(i), filenames[i]);

    ResponseText := IdHTTP1.Post(url, FormData);
    Memo1.Text := ResponseText; //debug
  finally
    FormData.Free;
  end;
end;

procedure TForm1.btnSendbyElastic(Sender: TObject);
var
  Params, Filenames : TStringList;
  url, Afilename : string;
begin
  Afilename := 'C:\Users\Admin\Documents\arrival and departure small.pdf';
  Params := TStringList.Create;
  try
    Params.Add('apikey=' + ELASTIC_MAIL_API_KEY);
    Params.Add('from=' + ELASTIC_EMAIL_FROM_EMAIL);
    Params.Add('fromname=' + ELASTIC_EMAIL_FROM_NAME);
    Params.Add('Subject=' + 'The Subject');
    Params.Add('bodyHtml=' + '<h1>Html Body</h1>');
    Params.Add('bodyText=' + 'Text Body');
    Params.Add('to=' + THE_RECIPIENT_ADDRESS);

    Filenames := TStringList.Create;
    try
      Filenames.Add(Afilename);

      url := ELASTIC_EMAIL_EMAIL_SEND;
      Upload(url, params, filenames);
    finally
      Filenames.Free;
    end;
  finally
    Params.Free;
  end;
end;

最后，Elastic 的文档没有说明文件名中包含非 ASCII/保留字符所需的编码。对于通过 HTTP 传输时如何编码此类文件名，存在相互冲突的标准。默认情况下，TIdMultipartFormDataStream 根据RFC 2047 对文件名进行编码。如果这对 Elastic 来说是个问题（您的示例文件名中包含空格字符，我忘记了 TIdMultipartFormDataStream RFC 是否由于空格对文件名进行编码，希望不是），您可以禁用 TIdMultipartFormDataStream' s 默认编码，将受影响文件的TIdFormDataField.HeaderEncoding 属性设置为'8'（8 位），然后您可以将TIdFormDataField.FileName 属性设置为您想要的任何编码：

with FormData.AddFile('file'+IntToStr(i), filenames[i]) do
begin
  HeaderEncoding := '8';
  FileName := EncodeFilenameMyWay(ExtractFileName(filenames[i]));
end;