OCaml 模式匹配中的变量隐藏

Question

我有一个方法可以返回列表中最常见元素的计数（特别是 char 值列表）

这是我的代码：

let getMostFrequentCharCount li =
    let hashTable = Hashtbl.create (List.length li)
    in
    let rec getMostFrequentCharCount li acc =
        match li with
            [] -> acc
            | head::tail ->
                (match (Hashtbl.find hashTable head) with
                    exception Not_found -> Hashtbl.add hashTable head 1
                    | _ -> let currentFreq = Hashtbl.find hashTable head 
                           in
                           Hashtbl.replace hashTable head (currentFreq+1));
                let currentFreq = Hashtbl.find hashTable head
                in
                if currentFreq > acc
                then
                    getMostFrequentCharCount tail currentFreq
                else
                    getMostFrequentCharCount tail acc
    in
    getMostFrequentCharCount li 0;;

由于某种原因，当我删除第二个模式匹配块（以 match (Hashtbl.find hashTable head) with 开头）周围的括号时，我的编译器抱怨我的累加器 acc 在下一个 if 语句 if currentFreq > acc 中有类型单元，而 @987654325 @ 应该有 int 类型。

为什么括号修复了这个错误？

Answer 1

在 OCaml 语法中，match 分支（在-> 之后）包含由; 分隔的表达式的序列。因此，如果没有括号，以下行将被解析为 _ 的 match 分支的一部分。

由于Hashtbl.add 返回单位，此匹配的第一个分支是单位类型。这意味着_ 分支也必须是单元类型。如果没有括号，以下几行会导致类型错误，因为它们不是 unit 类型。

我使用 ocamlformat 格式化外部 match 带和不带括号。

这是带括号的格式化代码：

match li with
| [] -> acc
| head :: tail ->
    ( match Hashtbl.find hashTable head with
    | exception Not_found -> Hashtbl.add hashTable head 1
    | _ ->
        let currentFreq = Hashtbl.find hashTable head in
        Hashtbl.replace hashTable head (currentFreq + 1) );
    let currentFreq = Hashtbl.find hashTable head in
    if currentFreq > acc then getMostFrequentCharCount tail currentFreq
    else getMostFrequentCharCount tail acc

这是没有括号的格式化代码：

match li with
| [] -> acc
| head :: tail -> (
    match Hashtbl.find hashTable head with
    | exception Not_found -> Hashtbl.add hashTable head 1
    | _ ->
        let currentFreq = Hashtbl.find hashTable head in
        Hashtbl.replace hashTable head (currentFreq + 1);
        let currentFreq = Hashtbl.find hashTable head in
        if currentFreq > acc then getMostFrequentCharCount tail currentFreq
        else getMostFrequentCharCount tail acc )

我认为这很好地说明了问题。