Erlang 主管不会重新启动子进程

Question

我正在尝试了解 erlang 主管。我有一个简单的printer process，每 3 秒打印一次 hello。如果发生任何异常，我还有一个主管必须重新启动printer process。

这是我的代码：

test.erl:

-module(test).
-export([start_link/0]).    

start_link() ->
    io:format("started~n"),
    Pid = spawn_link(fun() -> loop() end),
    {ok, Pid}.    

loop() ->
    timer:sleep(3000),
    io:format("hello~n"),
    loop().

test_sup.erl：

-module(test_sup).
-behaviour(supervisor).

-export([start_link/0]).
-export([init/1]).

start_link() ->
    supervisor:start_link({local, ?MODULE}, ?MODULE, []).    

init(_Args) ->
    SupFlags = #{strategy => one_for_one, intensity => 1, period => 5},    
    ChildSpecs = [#{id => test,
                    start => {test, start_link, []},
                    restart => permanent,
                    shutdown => brutal_kill,
                    type => worker,
                    modules => [test]}],    
    {ok, {SupFlags, ChildSpecs}}.

现在我运行这个程序并使用test_sup:start_link(). 命令启动主管，几秒钟后，我引发了一个异常。为什么主管不重启printer process？

这是shell输出：

1> test_sup:start_link().
started
{ok,<0.36.0>}
hello
hello
hello
hello          
2> erlang:error(err).

=ERROR REPORT==== 13-Dec-2016::00:57:10 ===
** Generic server test_sup terminating 
** Last message in was {'EXIT',<0.34.0>,
                           {err,
                               [{erl_eval,do_apply,6,
                                    [{file,"erl_eval.erl"},{line,674}]},
                                {shell,exprs,7,
                                    [{file,"shell.erl"},{line,686}]},
                                {shell,eval_exprs,7,
                                    [{file,"shell.erl"},{line,641}]},
                                {shell,eval_loop,3,
                                    [{file,"shell.erl"},{line,626}]}]}}
** When Server state == {state,
                            {local,test_sup},
                            one_for_one,
                            [{child,<0.37.0>,test,
                                 {test,start_link,[]},
                                 permanent,brutal_kill,worker,
                                 [test]}],
                            undefined,1,5,[],0,test_sup,[]}
** Reason for termination == 
** {err,[{erl_eval,do_apply,6,[{file,"erl_eval.erl"},{line,674}]},
         {shell,exprs,7,[{file,"shell.erl"},{line,686}]},
         {shell,eval_exprs,7,[{file,"shell.erl"},{line,641}]},
         {shell,eval_loop,3,[{file,"shell.erl"},{line,626}]}]}
** exception error: err

Answer 1

这是您使用文件创建的架构：

test_sup (supervisor)
  ^
  |
  v
 test (worker)

然后您通过在 shell 中调用 start_link() 来启动您的主管。这会创建另一个双向链接：

shell
  ^
  |
  v
test_sup (supervisor)
  ^
  |
  v
 test (worker)

通过双向链接，如果任何一方死亡，另一方就会被杀死。

当你运行 erlang:error 时，你的 shell 会出错！

你的 shell 链接到你的主管，所以 Erlang 杀死主管作为回应。通过连锁反应，你的工人也会被杀死。

我认为您打算将错误情况发送给您的工作人员而不是外壳：

1. 确定工作人员的 Pid：supervisor:which_children
2. 在工作人员的 Pid 上调用 erlang:exit(Pid, Reason)。

Answer 2

当你执行erlang:error(err).时，你正在杀死调用进程，你的shell。

因为你已经使用 start_link 启动了 supervisor，它也被杀死了，循环也被杀死了。

shell 会自动重新启动（感谢某些主管），但没有人重新启动您的测试主管，这无法重新启动循环。

要进行此测试，您应该：

在模块测试中：

start_link() ->
    Pid = spawn_link(fun() -> loop() end),
    io:format("started ~p~n",[Pid]),
    {ok, Pid}.

你会得到一个提示：

started <0,xx,0>

<0,xx,0> 是循环 pid，在 shell 中可以调用

exit(pid(0,xx,0), err).

仅终止循环。