Erlang 进程间消息传递

Question

我正在编写读取两个输入文件并检查第一个文件中的单词是否存在于第二个文件中的代码。我想通过进程消息传递来一一检查列表中的元素。

这是我的代码：

start()->
    Pid2 = spawn(?MODULE,check2,[]),
    spawn(?MODULE,check1,[Pid2]).

check1(Pid2) ->
    {ok, Data} = file:read_file("input.txt"),
    B = binary:split(Data, [<<" ">>], [global]),
    K = [binary_to_list(Item) || Item <- B],
    [Pid2 ! Element || Element <- K].

check2() ->
    {ok,IoDevice} = file:open("check.txt", [read]),
    L = string:tokens(io:get_line(IoDevice,""), "! ."),
    receive
        Element ->
            case lists:member(Element,L)of
                true ->
                    io:format(Element);
                false ->
                    io:format("not_ok")
            end
    end.

问题是当我想发送列表的一个元素时，它只发送第一个元素。如何修改我的代码以发送所有字符串并检查它们？

Answer 1

主要问题是您的check2/0 函数只接收一个元素然后退出。它需要循环接收所有元素，还需要告诉它何时停止。下面我们来一一改函数，从start/0开始：

start()->
    Pid2 = spawn(?MODULE,check2,[]),
    check1(Pid2).

这里的变化是不需要生成check2/1——它可以直接由start/0运行。

接下来，这是我们修改后的check1/1 函数：

check1(Pid2) ->
    {ok, Data} = file:read_file("input.txt"),
    B = binary:split(Data, [<<" ">>,<<"\n">>], [global,trim_all]),
    K = [binary_to_list(Item) || Item <- B],
    [Pid2 ! Element || Element <- K++[stop]].

首先，我们在拆分模式中添加了换行符，还添加了trim_all 选项以从拆分中删除空元素。我们还将原子stop 附加到我们发送给Pid2 的元素列表中。让我们看看我们修改后的check2/0 函数，看看为什么：

check2() ->
    {ok,IoDevice} = file:open("check.txt", [read]),
    L = string:tokens(io:get_line(IoDevice,""), "! .\n"),
    check2(L).

请注意，我们已将原始 check2/0 拆分为两个函数：check2/0 和 check2/1。这是因为check2/1 函数必须是递归的，因此它可以接收发送给它的所有元素：

check2(L) ->
    receive
        stop ->
            ok;
        Element ->
            case lists:member(Element,L)of
                true ->
                    io:format("found: ~s\n", [Element]);
                false ->
                    io:format("not found: ~s\n", [Element])
            end,
            check2(L)
    end.

请注意，在receive 内部，我们首先检查是否收到了原子stop，如果收到，我们退出函数。否则，我们接收并检查Element，然后递归调用check2/1，以便它可以接收下一个Element 或stop 原子。