如何在 Erlang 中使用 gen_udp 进行多播？答案

【问题标题】：How to multicast using gen_udp in Erlang?如何在 Erlang 中使用 gen_udp 进行多播？
【发布时间】：2010-09-09 21:07:00
【问题描述】：

你如何在 Erlang 中使用gen_udp 来做multicasting？我知道它在代码中，它背后没有文档。发送数据显而易见且简单。我想知道如何添加会员。不仅在启动时添加会员，在运行时添加会员也很有用。

【问题讨论】：

标签： networking erlang multicast

【解决方案1】：

组播由 IP 地址指定

在 erlang 和所有语言中都是一样的。 IP 地址 224.0.0.0 到 239.255.255.255 是多播地址。

在该范围内选择一个地址，检查您是否与已分配的地址重叠，然后就可以开始了。

http://www.iana.org/assignments/multicast-addresses

【讨论】：

嗯，我的意思是接受多播数据。这不是发送数据的问题。

【解决方案2】：

组播发送已应答，接收需要订阅组播组。

它（仍然）似乎没有记录，但之前已包含在 erlang-questions 邮件列表中。 http://www.erlang.org/pipermail/erlang-questions/2003-March/008071.html

    {ok, Socket} = gen_udp:open(Port, [binary, {active, false},
                                       {reuseaddr, true},{ip, Addr}, 
                                       {add_membership, {Addr, LAddr}}]).

其中Addr 是多播组，LAddr 是本地接口。（代码由 mog 提供）

上面使用的相同选项可以传递给inet:setopts，包括{drop_membership, {Addr, LAddr}}，以停止收听组。

【讨论】：

【解决方案3】：

这是关于如何监听 Bonjour / Zeroconf 流量的示例代码。

-module(zcclient).

-export([open/2,start/0]).
-export([stop/1,receiver/0]).

open(Addr,Port) ->
   {ok,S} = gen_udp:open(Port,[{reuseaddr,true}, {ip,Addr}, {multicast_ttl,4}, {multicast_loop,false}, binary]),
   inet:setopts(S,[{add_membership,{Addr,{0,0,0,0}}}]),
   S.

close(S) -> gen_udp:close(S).

start() ->
   S=open({224,0,0,251},5353),
   Pid=spawn(?MODULE,receiver,[]),
   gen_udp:controlling_process(S,Pid),
   {S,Pid}.

stop({S,Pid}) ->
   close(S),
   Pid ! stop.

receiver() ->
   receive
       {udp, _Socket, IP, InPortNo, Packet} ->
           io:format("~n~nFrom: ~p~nPort: ~p~nData: ~p~n",[IP,InPortNo,inet_dns:decode(Packet)]),
           receiver();
       stop -> true;
       AnythingElse -> io:format("RECEIVED: ~p~n",[AnythingElse]),
           receiver()
   end.

【讨论】：

【解决方案4】：

我尝试让这个示例在我的 PC 上运行。如果我通过打开接收套接字总是收到消息 {error,eaddrnotavail} 会发生什么？

示例 1：可行：

{ok, Socket} = gen_udp:open(?PORT, [{reuseaddr,true}, {ip,?SERVER_IP},
               {multicast_ttl,4}, {multicast_loop,false}, binary]),

示例 2：出现运行时错误：

{ok, Socket} = gen_udp:open(?PORT, [{reuseaddr,true}, {ip,?MULTICAST_IP},
               {multicast_ttl,4}, {multicast_loop,false}, binary]),

% --> {error,eaddrnotavail}

-define(SERVER_IP, {10,31,123,123}). % The IP of the current computer
-define(PORT, 5353).
-define(MULTICAST_IP, {224,0,0,251}).

【讨论】：

我在 Windows 上遇到了这个问题，但完全相同的代码在 Linux 上完美运行