提取变量名

Question

我们如何在 F# 中构建一个函数来输出传入的变量的名称？例如：

let someVar1 = "x"
getVarname someVar1 //output would be "someVar1"

let someVar2 = "y"
getVarname someVar2 //output would be "someVar2"

let f toString = fun a -> printfn "%s: %d" (toString a) a
let x = 1
f getVarname x      //output would be: "x: 1"

我在这里 (get name of a variable or parameter) 在 C# 中发现了一个类似的问题，但我无法在 F# 中使其工作。

Answer 1

nameof 实现在 F# 核心中具有运算符，但 F# 5 编译器位尚未发布。 当它出现时，您可以使用它来获取符号的名称。

let someVar1 = None
let name = nameof someVar1 // name = "someVar1"

目前，我们可能会滥用动态运算符为我们提供一个 shim，您最终可以将其替换为 nameof

let name = ()
let (?) _ name = string name

用法：

let someVar1 = None
let name = name?someVar1

它读起来还不错，而且你会得到某种程度的自动完成。

如果您真的希望能够在调用站点检索本地名称和值，可以使用引号。

let printVar = function
|  ValueWithName(value, _type, name) -> printfn "%s = %A" name value 
| _ -> ()

不过使用起来有点吵。

let someVar1 = 12
printVar <@ someVar1 @> //prints someVar1 = 12

Answer 2

如果您使用引号和静态方法，您已经可以使用ReflectedDefinition 属性在 F# 4 中捕获变量的名称。以下示例中的Demo.GetVarName 静态方法返回用作参数的变量的名称和值：

open Microsoft.FSharp.Quotations

type Demo = 
  static member GetVarName([<ReflectedDefinition(true)>] x:Expr<int>) = 
    match x with
    | Patterns.WithValue(_, _, Patterns.ValueWithName(value, _, name)) ->
        name, value :?> int
    | _ -> failwithf "Argument was not a variable: %A" x

let test ()= 
  let yadda = 123
  Demo.GetVarName(yadda)

test()

这适用于上面的test() 函数中的局部变量。对于顶级变量（实际上编译为属性），您还需要为PropertyGet 添加一个案例：

match x with
| Patterns.WithValue(_, _, Patterns.ValueWithName(value, _, name)) -> 
    name, value :?> int
| Patterns.WithValue(value, _, Patterns.PropertyGet(_, pi, _)) -> 
    pi.Name, value :?> int
| _ -> failwithf "Argument was not a variable: %A" x