使用 Racket 构建过滤器内置功能

Question

我正在尝试使用 Racket 构建过滤器（内置函数），只是作为一种实践。

我创建了以下代码：

(define (filter lista-1 check-function)
 (define (fil-iter lista-1 check-function lista-2)
  (cond ((null? lista-1) lista-2)
        ((check-function (car lista-1)) (fil-iter (cdr lista-1) check-function (append lista-2 (list (car lista-1)))))
        (else (fil-iter (cdr lista-1) check-function lista-2))))
   (trace fil-iter)
   (fil-iter lista-1 check-function '()))

我用“奇数？”、“偶数？”做了一些测试。和“号码？”作为“检查功能”。

所有输出都是正确的。但我可能什么都没看到……我的直觉说这里有问题。

Answer 1

可以使用for/list 和#:when 子句来创建过滤函数：

(define (myfilter proc lst)
  (for/list ((item lst)
             #:when (proc item))
    item))

(myfilter even? '(1 2 3 4 5 6))
; => '(2 4 6)

Answer 2

您的函数是正确的，只是它的复杂度为 n²，而它的复杂度可能为 n。

原因是您使用append 而不是cons 来构建结果，而append 的成本与列表的长度成正比，而cons 的成本是恒定的。因此，如果您想要一个具有线性复杂度的函数，您应该编写如下内容：

(define (filter lista-1 check-function)
 (define (fil-iter lista-1 check-function lista-2)
  (cond ((null? lista-1) (reverse lista-2))
        ((check-function (car lista-1))
         (fil-iter (cdr lista-1) check-function (cons (car lista-1) lista-2)))
        (else (fil-iter (cdr lista-1) check-function lista-2))))
   (fil-iter lista-1 check-function '()))

请注意，最后结果必须取反，但这不会改变函数的复杂度，因为reverse 具有与列表大小呈线性关系的复杂度，并且只在函数末尾执行一次.

您还可以简化函数，注意参数check-function 在每次调用帮助程序fil-iter 时都不会修改，因此可以在其中省略：

(define (filter lista-1 check-function)
 (define (fil-iter lista-1 lista-2)
  (cond ((null? lista-1) (reverse lista-2))
        ((check-function (car lista-1))
         (fil-iter (cdr lista-1) (cons (car lista-1) lista-2)))
        (else (fil-iter (cdr lista-1) lista-2))))
   (fil-iter lista-1 '()))