有没有办法将这个函数重写为全部？

Question

我有一个函数，如下所示，Code Review 上的某个人建议我将其重写为完全。他们建议对getRow 和(!) 的调用可以替换为对zip 或fold 的调用。

我已经考虑过这个问题，但我真的不知道如何以这种方式重写它，我也不知道如何自学如何重写它。

import Data.Matrix (Matrix, getRow, ncols)
import Data.Vector ((!))

type AdjacencyMatrix = Matrix Bool

-- Input: the graph's adjacency matrix and a vertex. 
-- Output: the list of neighbours of that vertex.
neighbours :: AdjacencyMatrix -> Int -> [Int]
neighbours mat n = filter (\m -> row ! m) [0..(ncols mat)-1]
        where row = getRow n mat

此代码 sn-p 在我的程序上下文中工作，但如果 n 大于 (ncols mat) - 1 则某些 row ! m 调用将失败。

Answer 1

您可以使用safeGetRow :: Matrix a -> Maybe (Vector a)，它会在索引超出范围时返回Nothing。

问题当然是如果索引超出范围我们该怎么做。两个合理的选择是：

1. 使用Maybe [Int]而不是[Int]作为返回类型并返回一个Nothing；或
2. 返回一个空列表，因为如果节点不在邻接矩阵中，则它没有邻居。

例如，我们可以将其实现为：

import Data.Matrix(Matrix, safeGetRow)
import Data.Vector(toList)

neighbours :: AdjacencyMatrix -> Int -> Maybe [Int]
neighbours mat n = map fst . filter snd . zip [0..] . toList <$> safeGetRow n mat

我们在这里使用toList :: Vector a -> [a] 来防止使用(!) :: Vector a -> Int -> a 这看起来不安全：您使用了正确的索引，但这需要一些推理，而toList 是一个总函数，因此显然总会产生结果。

我们可以通过使用findIndices :: (a -> Bool) -> Vector a -> Vector Int 使其更紧凑：

import Data.Matrix(Matrix, safeGetRow)
import Data.Vector(findIndices, toList)

neighbours :: AdjacencyMatrix -> Int -> Maybe [Int]
neighbours mat n = toList . findIndices id <$> safeGetRow n mat

或者我们可以使用maybe :: b -> (a -> b) -> Maybe a -> b 来代替空列表：

import Data.Matrix(Matrix, safeGetRow)
import Data.Maybe(maybe)
import Data.Vector(findIndices, toList)

neighbours :: AdjacencyMatrix -> Int -> [Int]
neighbours mat n = maybe [] (toList . findIndices id) (safeGetRow n mat)