如何使用 PL/SQL 修改 XML 目标文件的标头？

Question

我有一个将数据从 Oracle 表导出到 XML 目标的过程。使用的代码是：

ctx := DBMS_XMLGEN.newcontext (v_sql_text);
   DBMS_XMLGEN.setnullhandling (ctx, 0);
   DBMS_XMLGEN.setrowsettag (ctx, 'RENTAL_Set');
   DBMS_XMLGEN.setrowtag (ctx, 'RENTAL_Record');
   xmldoc := DBMS_XMLGEN.getxml (ctx);
   DBMS_XSLPROCESSOR.clob2file (xmldoc,
                                'path',
                                v_file_name,
                                0);
   DBMS_XMLGEN.closecontext (ctx);

我得到目标文件的第一行： <?xml version="1.0"?> 我需要它 <?xml version="1.0" encoding="UTF-8"?>

我怎样才能做到这一点？

Answer 1

将DBMS_XMLQuery 用作：

qryCtx := DBMS_XMLQuery.newContext(v_sql_text);

DBMS_XMLQuery.setNullAttributeIndicator(qryCtx, FALSE);
DBMS_XMLQuery.setEncodingTag(qryCtx, 'UTF-8');
DBMS_XMLQuery.setRowsetTag(qryCtx, 'RENTAL_Set');
DBMS_XMLQuery.setRowTag(qryCtx, 'RENTAL_Record');
o_results := DBMS_XMLQuery.getXML(qryCtx);

DBMS_XSLPROCESSOR.clob2file (o_results, 'path', v_file_name, 0);

DBMS_XMLQuery.closeContext(qryCtx);

[编辑]

要保留 DBMS_XMLGEN 结构，请使用此代码块（感谢@AlexPoole）：

declare
   ctx dbms_xmlquery.ctxHandle;
   xmldoc clob;
   v_sql_text varchar2(4000) := 'select * from dual';
begin
   ctx := DBMS_XMLQuery.newContext(v_sql_text);

   DBMS_XMLQuery.useNullAttributeIndicator(ctx, FALSE);
   DBMS_XMLQuery.setEncodingTag(ctx, 'UTF-8');
   DBMS_XMLQuery.setRowsetTag(ctx, 'RENTAL_Set');
   DBMS_XMLQuery.setRowTag(ctx, 'RENTAL_Record');
   DBMS_XMLQuery.setRowIDAttrName(ctx, null);

   xmldoc := DBMS_XMLQuery.getXML(ctx);
  -- dbms_output.put_line(xmldoc);
   DBMS_XSLPROCESSOR.clob2file (xmldoc, 'path', v_file_name, 0);

   DBMS_XMLQuery.closecontext (ctx);
end;
/

Answer 2

我认为没有办法直接通过dbms_xmlgen。但是您可以通过 BLOB 反弹生成的 XML，并将字符集指定为其中的一部分；而不是：

   xmldoc := DBMS_XMLGEN.getxml (ctx);

您可以使用额外的 XMLType 变量和上下文切换：

declare
...
   xml xmltype;
begin
...
   xml := DBMS_XMLGEN.getxmltype (ctx);
   select xmlserialize(
      content
         xmltype(
            xml.getblobval(nls_charset_id('UTF8')),
            nls_charset_id('UTF8'))
        version '1.0')
   into xmldoc
   from dual;

然后得到：

<?xml version="1.0" encoding="UTF-8"?>
<RENTAL_Set>
  <RENTAL_Record>
    ...
  </RENTAL_Record>
</RENTAL_Set>

db<>fiddle

xml 值是从同一来源生成的；现在它只是一个 XMLType 而不是 CLOB。然后将其转换为指定字符集 UTF8 的 BLOB。该 BLOC 被转换回 XMLType，但现在它知道字符集。 （感觉应该有一种方法可以跳过其中的一些步骤......）而且因为它现在是基于 BLOB 的 XMLType，所以 XMLSerialize 包含了编码。这会生成一个 CLOB，您可以将其分配给 xmldoc - 然后继续进行文件写入或您需要的任何其他处理。