如何定义多个emacs面？答案

【问题标题】：How to define multiple emacs faces?如何定义多个emacs面？
【发布时间】：2013-11-28 19:31:56
【问题描述】：

我正在尝试定义一些 emacs 字体来进行一些自定义突出显示。当我单独定义它们时，这似乎有效：

(defface my-r-face `((t (:foreground "red")))  "Red highlight")
(defvar m-r-face 'my-r-face "Red.")
(defface my-g-face `((t (:foreground "green")))  "Green highlight")
(defvar m-g-face 'my-g-face "Green.")
(defface my-b-face `((t (:foreground "#0088ff")))  "Blue highlight")
(defvar m-b-face 'my-b-face "Blue.")
....etc

但是我有几十个，我想从某种颜色表中一次性定义它们：

(setq ctable '(("red" "r")
           ("orange" "o")
           ("yellow" "y")
           ("#88ff00" "gy")
           ("green" "g")
           ("#00ff88" "gc")
           ("cyan" "c")
           ("#0088ff" "bc")
           ("blue" "b")
           ("purple" "bm")
           ("magenta" "m")
           ("#ff0088" "rm")
           ("grey" "lg")
           ("white" "w") ))

我的困难在于为每个面组装符号名称，即将“my-”和“-face”连接到表格条目的任一侧。我发现（实习生）可以从字符串中创建一个新符号，但是这个符号对于（defface）来说是不可接受的，因为我正在做的似乎等同于（defface'my-r-face ...，并且 defface 不喜欢引用的符号，并且期望 (defface my-r-face .. 代替。我的尝试如下：

(dolist (tpl ctable)
  (defvar (intern (concat "my-" (nth 1 tpl) "-face"))
    (quote (intern (concat "my-" (nth 1 tpl) "-face"))) "colour")
  (defface (intern (concat "my-" (nth 1 tpl) "-face"))
    `((t (:foreground ,(car tpl)))) "Highlight" :group 'fortran)
)

运行这个结果

Lisp error: (wrong-type-argument symbolp (intern (concat "fegs-" (nth 1 tpl) "-face")))
  (defvar (intern (concat "fegs-" ... "-face")) (quote (intern ...)) "colour")

谁能解释一下我做错了什么，或者我是否完全找错了树并且有更好的方法来做到这一点？

谢谢。

【问题讨论】：

请不要做“defvar”的事情：你只需要“defface”。由于各种原因，这是为 font-lock 使用的原始面孔做的，从那时起每个人都复制了这个错误。
如果我删除了 defvar（或我下面代码中的变体），那么所有突出显示都不能正常工作。这是由于其余模式中使用的机制造成的吗？它通过将面孔和一些关键字正则表达式添加到列表中来继续，然后在字体锁定的内部使用该列表，并且没有 defvar 这将停止工作。
那是因为你的字体锁定规则是错误的：他们可能需要说'my-r-face而不是my-r-face。

标签： emacs emacs-faces

【解决方案1】：

defvar 是一种特殊形式，defface 是一个宏（因此参数传递时未计算）。您是否尝试过使用

(eval `(defface ,(intern "foo") '((t (:foreground "red"))) "Highlight" :group 'fortran))

(eval `(defvar ,(intern "bar")))

【讨论】：

我试图避免 eval，在这种情况下它真的是适合这项工作的工具吗？
我不知道足够多的 lisp 来声称（甚至不知道） eval 是完成这项工作的正确工具。我只是认为这是一个合适的工具:-)。

【解决方案2】：

最终工作的完整代码如下：

(setq ctable '(("red" "r")
           ("orange" "o")
           ("yellow" "y")
           ("#88ff00" "gy")
           ("green" "g")
           ("#00ff88" "gc")
           ("cyan" "c")
           ("#0088ff" "bc")
           ("blue" "b")
           ("purple" "bm")
           ("magenta" "m")
           ("#ff0088" "rm")
           ("grey" "lg")
           ("white" "w") ))

(dolist (tpl ctable)
  (let ((fname (concat "fegs-" (nth 1 tpl) "-face")))
    (eval `(defface ,(intern fname) '((t (:foreground ,(car tpl)))) "Highlight" :group 'fortran))
    (eval `(defvar ,(intern fname) ',(intern fname)))
  )
)

我的 defvar 行略有不同，因为这允许人脸被其他地方的突出显示代码拾取为全局变量。

【讨论】：

正如上面@Stefan 所指出的，只要在使用它的字体锁定定义中引用了面部名称，defvar 行就不是必需的。

【解决方案3】：

你可以避开eval：

(defconst my-ctable '(...))

(defmacro my-init-cfaces ()
  `(progn
    ,@(mapcar (lambda (tpl)
               `(defface ,(intern (format "my-%s-face" (nth 1 tpl)))
                  '((t :foreground ,(car tpl)))
                  ,(format "Face for color %s." (car tpl))
                  :group 'fortran))
              my-ctable)))

(my-init-cfaces)

【讨论】：