TIdHTTP 发布到 API 并将响应保存为 .pdf 文件

Question

根据提供的文档，我正在调用 API URL 和一些 parameters。

按照 API 的设置方式，响应应该是自动下载 .pdf 文件。

参数为：

• number - 代表 13 位数字，代表系统中的唯一文件指示符（例如：5277110610029）
• username 和 user_pass 分别代表访问系统的登录凭据
• client_id - 代表在他们的系统中与我的帐户关联的唯一客户 ID
• language - 我指出文件内容应使用的语言（英语或其他可用语言）

文档表明它应该作为Post 请求。

我有以下代码：

var
FileName : string;
URL: String;
Params: TStringList;
memStream: TMemoryStream;
...

begin
FileName:= MainModule.PDFfileName + '.pdf';

 begin
 URL := 'https://someURL/view_integrated_pdf.php?';
 Params := TStringList.Create;
 memStream := TMemoryStream.Create;

  try
  Params.Add('number='+MainModule.number+'');
  Params.Add('username='+MainModule.User+'');
  Params.Add('client_id='+MainModule.clientID+'');
  Params.Add('user_pass='+MainModule.Pass+'');
  Params.Add('language=en');

  MainModule.IdHTTP.Post(URL, Params, memStream);

  finally
  memStream.SaveToFile(ServerModule.FilesFolderPath+'\pdfs\'+FileName);
  Params.Free;
  memStream.Free;

  end;
 end;

pdfForm.ShowModal();

end;

如果我在浏览器中尝试生成的 URL 和 parameters - 它会自动下载 API 给我的名为 numberParameter.pdf 的 pdf 文件

如果我使用提供的代码在 Delphi 中执行此操作，则 10 次中有 8 次会保存 pdf file 和 1 KB Size（通常它在成功文件的 32 和 100 之间）并且当我尝试使用我的pdfForm 和随后的viewer 在程序中打开它，查看器会抛出错误"Invalid PDF structure"

• 我做错了什么？ / 如何正确保存返回 .pdf 文件以从 API 下载的 Post 请求？

更新

根据 cmets，在 Notepad++ 中打开 1kb 生成的 PDF 会简单地将内容显示为 Error username.

这令人费解，因为我检查过并且传递的用户名是准确的 + 如果我在浏览器中粘贴带有参数值的完全相同的 URL，它可以完美运行并为我提供正确的 PDF。

• 我的代码不是正确的发布和保存正在发送的文件的方法吗？

Answer 1

如果我在浏览器中尝试生成的 URL 和 parameters - 它会自动下载 API 给我的名为 numberParameter.pdf 的 pdf 文件

在浏览器中执行此操作的唯一方法是将参数放入 URL 的查询组件中，例如：

https://someURL/view_integrated_pdf.php?number=...&username=...&client_id=...&user_pass=...&language=en

... 而不是在 POST 正文中，就像您的代码所做的那样。此外，浏览器会发送GET 请求，而不是POST 请求。除非您正在填写 HTML 网络表单（即<form action="<URL>" method="POST" ...>）并提交它。这就是 API 文档所说的吗？

由于您没有从文档中提供有关此服务器实际期望的任何详细信息，因此我们无法真正告诉您您的代码是正确还是错误。但您的手动测试似乎与您声称的文档所说的服务器所期望的相矛盾。

如果我使用提供的代码在 Delphi 中执行此操作，则 10 次中有 8 次会保存 1 KB 大小的 pdf 文件（成功文件通常在 32 到 100 之间），当我尝试打开它时使用我的 pdfForm 和后续查看器的程序，查看器会抛出错误“无效的 PDF 结构”

来自 cmets，您说您的文件正在接收文本错误消息。 TIdHTTP 会将此类文本保存到您的 TMemoryStream ONLY IF：

• HTTP 服务器不在 HTTP 级别报告错误，即它正在使用 HTTP 2xx 成功响应发送文本消息。我怀疑这就是你的情况。默认情况下，如果服务器使用正确 HTTP 错误代码，TIdHTTP 将引发包含文本消息的EIdHTTPProtocolException，并且NOT 将文本保存到您的TMemoryStream完全没有。

• HTTP 服务器 IS 在 HTTP 级别报告错误，但您在 TIdHTTP.HTTPOptions 属性中同时使用了 hoNoProtocolErrorException 和 hoWantProtocolErrorContent 标志。在这种情况下，TIdHTTP 不会引发EIdHTTPProtocolException，而是将服务器发送的任何数据原样保存到您的TMemoryStream。

由于显然没有引发 HTTP 异常，您必须先验证服务器的响应，然后才能使用 pdfForm 中的下载数据，即通过查看 TIdHTTP.Response.ContentType 和/或 TIdHTTP.Response.ContentDisposition 属性来知道服务器是否真的发送了 PDF 文件。

这令人费解，因为我检查过并且传递的用户名是准确的 + 如果我在浏览器中粘贴带有参数值的完全相同的 URL，它可以完美运行并为我提供正确的 PDF。

好吧，一方面，您的代码中有一个错字：numberr 字段需要改为 number。

除此之外，将 URL 放入浏览器与您的代码正在执行的操作不同，因此请尝试更改您的代码以模仿您手动执行的操作，例如：

uses
  ..., IdGlobalProtocols, IdHTTP, IdURI;

...

var
  URL : string;
  memStream: TMemoryStream;
begin
  // All parameters into the URI for a HTTP GET request
  URL := 'https://someURL/view_integrated_pdf.php'
       + '?number=' + TIdURI.ParamsEncode(MainModule.number)
       + '&username=' + TIdURI.ParamsEncode(MainModule.User)
       + '&client_id=' + TIdURI.ParamsEncode(MainModule.clientID)
       + '&user_pass=' + TIdURI.ParamsEncode(MainModule.Pass)
       + '&language=en';

  memStream := TMemoryStream.Create;
  try
    MainModule.IdHTTP.Get(URL, memStream);

    // Is it really PDF? Other formats such as plaintext is not wanted.
    if not IsHeaderMediaType(MainModule.IdHTTP.ContentType, 'application/pdf') then Exit;

    memStream.SaveToFile(ServerModule.FilesFolderPath + '\pdfs\' + MainModule.PDFfileName + '.pdf');
  finally
    memStream.Free;
  end;

  pdfForm.ShowModal;
end;

如果这不起作用，请更新您的问题以提供实际文档。