Delphi - 无需下载即可显示图像[重复]

Question

可能重复：
How to get images from URL in Delphi

我使用的是 Delphi 2010，有一些功能我可以下载并以 cximage 或图像对象的形式显示 JPG 或 PNG 图片，但我试图不将图片下载到硬盘驱动器，我想知道是那可能吗？我通过谷歌和stackoverflow搜索但找不到，所有示例都是关于下载文件的。

例如，我在表单中添加了一个 cximage1，并希望显示来自“http://www.someaddress.com/pictures/001.JPG”之类的 url 的图片。

感谢大家的帮助，抱歉英语不好:)

Answer 1

您可以使用此函数（使用 Delphi 2010 编译和测试）通过 HTTP 下载文件并将其存储在 TBitMap 中。它将读取在 Delphi 的 TGraphic hiearachy 中注册支持的所有文件类型，并自动检测 BMP、GIF、JPG 和 PNG 文件格式：

USES Graphics, IdHTTP, PngImage, jpeg, GIFImg;

FUNCTION DownloadImage(CONST URL : STRING ; ImageType : TGraphicClass = NIL) : TBitMap;
  VAR
    HTTP        : TIdHttp;
    S           : TStream;
    IMG         : TGraphic;
    STR         : AnsiString;

  BEGIN
    HTTP:=TIdHttp.Create(NIL);
    TRY
      S:=TMemoryStream.Create;
      TRY
        HTTP.Get(URL,S);
        IF NOT Assigned(ImageType) THEN BEGIN
          S.Position:=0;
          SetLength(STR,5);
          S.Read(STR[1],LENGTH(STR));
          IF COPY(STR,1,2)='BM' THEN
            ImageType:=TBitMap
          ELSE IF COPY(STR,1,3)='GIF' THEN
            ImageType:=TGIFImage
          ELSE IF COPY(STR,2,3)='PNG' THEN
            ImageType:=TPngImage
          ELSE IF (ORD(STR[1])=$FF) AND (ORD(STR[2])=$D8) THEN
            ImageType:=TJPEGImage
        END;
        IF NOT Assigned(ImageType) THEN RAISE EInvalidImage.Create('Unrecognized file format!');
        IMG:=ImageType.Create;
        TRY
          S.Position:=0;
          IMG.LoadFromStream(S);
          Result:=TBitMap.Create;
          TRY
            Result.Assign(IMG)
          EXCEPT
            Result.Free;
            RAISE
          END
        FINALLY
          IMG.Free
        END
      FINALLY
        S.Free
      END
    FINALLY
      HTTP.Free
    END
  END;

如果您已经知道文件类型，则可以将其指定为 TGifImage、TPngImage、TJPegImage 或 TBitMap 作为第二个参数。如果不是，例程将尝试在这四种类型中自动检测它。如果您使用自定义图形类型，则需要将其指定为第二个参数或更新自动检测逻辑以检测它。

因此，如果您想使用它在 TImage 中显示下载的图像而不将其保存到光盘，您可以这样使用它：

  VAR
    BMP : TBitMap;

  BEGIN
    BMP:=DownloadImage('http://domain.com/image.jpg');
    TRY
      Image1.Picture.Assign(BMP)
    FINALLY
      BMP.Free
    END
  END;