使用 VBA 设置条件格式和高亮

Question

如果 K 列小于 L 列，是否可以使用 VBA 设置条件格式以突出显示 Excel 电子表格中的行或单元格？

我在搜索时出现的前几个谷歌页面上有一条路线，但我什么也做不了:(

Sub SpecCheck()
Dim iRow As Range, cell as Range ' I also added the cell as Range
Set iRow = Range("$J$2:$L$50")

For Each cell In iRow
    If cell.Value <> "" And cell.Value > Range("$L$2").Value And cell.Value < Range("$K$2").Value Then
        cell.Interior.Color = RGB(255, 0, 0)
    End If
Next
End Sub

任何帮助将不胜感激

Answer 1

请尝试下一个代码：

Sub SpecFormatConditions()
 Dim rng As Range, condition1 As FormatCondition

 Set rng = Range("K2:K10")
  
  With rng
    .FormatConditions.Delete
    Set condition1 = .FormatConditions.Add(Type:=xlExpression, Formula1:="=And(" & _
             .cells(1).Address(0, 0) & "<>"""", " & .cells(1).Address(0, 0) & ">" & _
             .cells(1).Offset(0, 1).Address(0, 0) & ")")
  End With
   With condition1
    .Interior.Color = RGB(255, 0, 0)
   End With
End Sub

要修改更大范围的内部（就列而言），必须使用包含列绝对引用的公式：

Sub SpecFormatConditionsThreColumns()
 Dim rng As Range, condition1 As FormatCondition

 Set rng = Range("J2:L10")
  
  With rng
    .FormatConditions.Delete
    Set condition1 = .FormatConditions.Add(Type:=xlExpression, Formula1:="=And($K2 <>"""", $K2 < $L2)")
  End With
   With condition1
    .Interior.Color = RGB(255, 0, 0)
   End With
End Sub