未应用条件格式

Question

如果填充了某些单元格，我正在尝试将规则应用于模板的列，然后格式将使用公式的值/地址。在这一点上我有点迷茫，因为其他一切都在正常工作，我没有收到任何错误。 QAcol 在用于填充这些单元格的代码中较早地生成。任何将工作表指定为条件格式范围的尝试都会导致对象定义错误，我不知道为什么。

Dim CFQcol As Integer
Dim j As Integer


wb.Sheets("QA Data").Activate
row = 0
col = 0

For CFQcol = 17 To QAcol
    If IsEmpty(wb.Sheets("QA Data").Cells(3, CFQcol)) = False And InStr(wb.Sheets("QA Data").Cells(3, CFQcol).Value, "Repo") = 0 Then
        j = 1
        If IsEmpty(wb.Sheets("QA Data").Cells(4, CFQcol)) = False Then
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:=Cells(4, CFQcol).Address
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions(j).Font.Color = RGB(255, 0, 0)
            j = j + 1
            End If
        If IsEmpty(wb.Sheets("QA Data").Cells(7, CFQcol)) = False Then
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:=Cells(7, CFQcol).Address
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions(j).Font.Color = RGB(0, 0, 200)
            j = j + 1
            End If
        If IsEmpty(wb.Sheets("QA Data").Cells(5, CFQcol)) = False Then
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:=Cells(5, CFQcol).Address
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions(j).Font.Color = RGB(255, 0, 0)
            j = j + 1
            End If
        If IsEmpty(wb.Sheets("QA Data").Cells(8, CFQcol)) = False Then
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:=Cells(8, CFQcol).Address
            Range(Cells(11, CFQcol), Cells(10000, CFQcol)).FormatConditions(j).Font.Color = RGB(0, 0, 200)
            End If
    End If
Next

感谢您的帮助！

Answer 1

Range 默认使用活动工作表。您正在混合隐式和显式引用。尽可能使用显式引用。除非您为用户移动视图，否则您永远不必.Activate。您在最后一个块上缺少j = j + 1。让我们将 j = 1 移到循环之外，因为您每次都将添加更多条件格式。

注意：添加大量条件格式是个坏主意。它会减慢您的工作簿并使其在某些时候无法使用。

当我运行我的测试代码时，格式确实将文本更改为红色。如果不查看您的数据并更好地了解最终结果，就很难判断代码是否正在执行您想要的操作。

Dim CFQcol As Integer
Dim j As Integer

Dim qaData As Worksheet
Set qaData = wb.Sheets("QA Data")

row = 0
col = 0
j = 1

For CFQcol = 17 To QAcol
    If Not IsEmpty(qaData.Cells(3, CFQcol)) And InStr(qaData.Cells(3, CFQcol).Value, "Repo") = 0 Then

        If Not IsEmpty(qaData.Cells(4, CFQcol)) Then
            With qaData.Range(Cells(11, CFQcol), Cells(10000, CFQcol))
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:=qaData.Cells(4, CFQcol).Address
                .FormatConditions(j).Font.Color = RGB(255, 0, 0)
            End With
            j = j + 1
        End If
        
        If Not IsEmpty(qaData.Cells(7, CFQcol)) Then
            With qaData.Range(Cells(11, CFQcol), Cells(10000, CFQcol))
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlGreater, Formula1:=qaData.Cells(7, CFQcol).Address
                .FormatConditions(j).Font.Color = RGB(0, 0, 200)
            End With
            j = j + 1
        End If
        
        If Not IsEmpty(qaData.Cells(5, CFQcol)) Then
            With qaData.Range(Cells(11, CFQcol), Cells(10000, CFQcol))
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:=qaData.Cells(5, CFQcol).Address
                .FormatConditions(j).Font.Color = RGB(255, 0, 0)
            End With
            j = j + 1
        End If
        
        If Not IsEmpty(qaData.Cells(8, CFQcol)) Then
            With qaData.Range(Cells(11, CFQcol), Cells(10000, CFQcol))
                .FormatConditions.Add Type:=xlCellValue, Operator:=xlLess, Formula1:=qaData.Cells(8, CFQcol).Address
                .FormatConditions(j).Font.Color = RGB(0, 0, 200)
            End With
            j = j + 1
        End If
    End If
Next