Excel 2013 条件格式 NOT() 运算符似乎不起作用答案

【问题标题】：Excel 2013 Conditional Formating NOT() operator does not seem to workExcel 2013 条件格式 NOT() 运算符似乎不起作用
【发布时间】：2017-07-28 07:45:34
【问题描述】：

我对以下内容感到困惑。我一定是做错了什么，但看不到什么。

这行得通

=FIND(A$6,CONCATENATE($A$2,$B$2,$C$2,$D$2,$E$2,$F$2,$G$2,$H$2,$I$2,$J$2,$K$2,$L$2,$M$2))

这不起作用

=NOT(FIND(A$6,CONCATENATE($A$2,$B$2,$C$2,$D$2,$E$2,$F$2,$G$2,$H$2,$I$2,$J$2,$K$2,$L$2,$M$2)))

一切都一样，范围相同，唯一的区别是 NOT() 运算符应该将条件从 TRUE 更改为 FALSE，并突出显示 FIND() 结果不为 TRUE 的单元格。

【问题讨论】：

标签： excel formatting conditional

【解决方案1】：

FIND 函数不返回 TRUE 或 FALSE - 它返回搜索值的位置（一个数字），如果搜索值不存在，则返回 #VALUE! 错误

它在条件格式中按要求工作，因为任何非零数值结果都相当于TRUE（而零是FALSE）

如果找到搜索值，使用此版本以条件格式返回 TRUE 可能更容易理解：

=ISNUMBER(FIND(A$6,CONCATENATE($A$2,$B$2,$C$2,$D$2,$E$2,$F$2,$G$2,$H$2,$I$2,$J$2,$K$2,$L$2,$M$2)))

所以反过来，你可以使用ISERROR函数，即

=ISERROR(FIND(A$6,CONCATENATE($A$2,$B$2,$C$2,$D$2,$E$2,$F$2,$G$2,$H$2,$I$2,$J$2,$K$2,$L$2,$M$2)))

注意：如果您希望值 A6 等于 A2:M2 值之一，则使用 COUNTIF 可能更容易，例如

=COUNTIF($A$2:$M$2,A$6)>0

和

=COUNTIF($A$2:$M$2,A$6)=0

【讨论】：

非常感谢巴里，这是我犯的一个愚蠢的错误。并感谢您提供 COUNTIF() 更好的解决方案，我的在从 Test 查找时不会突出显示像 Test 和 Test2 这样的单元格，因为它会在 Test2 中找到它。