如何在 Nixos configuration.nix 中覆盖 2（两个）包

Question

我的 configuration.nix 中有一些包要覆盖。所以我写代码如下：

nixpkgs.config = {
  allowUnfree = true;
  packageOverrides = {
    pkgs: rec {
      #mumble + pulse audio
      mumble = pkgs.mumble.override {
        pulseSupport = true;
      };

      #kernel for intel ethernet and Testing e1000e package override
      linuxPackages.e1000e = pkgs.linuxPackages.e1000e.overrideDerivation (attrs: {
        name = "e1000e-3.3.3-${config.boot.kernelPackages.kernel.version}";
        src = fetchurl {
          url = "https://www.dropbox.com/s/pxx883hx9763ygn/e1000e-3.3.3.tar.gz?dl=0";
          sha256 = "1s2w54927fsxg0f037h31g3qkajgn5jd0x3yi1chxsyckrcr0x80";
        };
      });
    };
  };
};

但是当我执行nixos-rebuild switch 时，出现以下错误：

syntax error, unexpected ':', expecting '.' or '=', at 37,11

位于pkgs: rec {...

我做错了什么？一开始我是通过像这样分隔 pkg 来写的：

packageOverrides = {
  pkgs: with pkgs: {......}; #this is for mumble
  pkgs: rec {...}; #this is for kernel
};

仍然出现同样的错误。

Answer 1

正确的解决办法是：

nixpkgs.config = {

  allowUnfree = true;

  packageOverrides = super: let self = super.pkgs; in {

    mumble = super.mumble.override { pulseSupport = true; };

    linuxPackages = super.linuxPackages // {
      e1000e = super.linuxPackages.e1000e.overrideDerivation (old: {
        name = "e1000e-3.3.3-${config.boot.kernelPackages.kernel.version}";
        src = fetchurl {
          url = "https://www.dropbox.com/s/pxx883hx9763ygn/e1000e-3.3.3.tar.gz?dl=0";
          sha256 = "1s2w54927fsxg0f037h31g3qkajgn5jd0x3yi1chxsyckrcr0x80";
        };
      });
    };
  };
}

变量super 指的是Nixpkgs 集之前 应用了覆盖，self 引用它之后 应用了覆盖。明确区分这两者以避免无限递归等很重要。

另外，请注意您的覆盖

linuxPackages.e1000e = pkgs.linuxPackages.e1000e.overrideDerivation ...

将linuxPackages 属性集替换为只包含（重写的）e1000e 派生的属性集。这可能不是你想要的。