如何从 VB.NET 运行 DOS/CMD/命令提示符命令？

Question

这个问题是不言自明的。如果代码只有一行，那就太好了（与“Process.Start("...")”有关？）。我研究了网络，但只发现了旧的例子和那些不起作用的例子（至少对我来说）。我想在我的类库中使用它来运行 Git 命令（如果有帮助？）。

Answer 1

你可以试试这个方法：

Public Class MyUtilities
    Shared Sub RunCommandCom(command as String, arguments as String, permanent as Boolean) 
        Dim p as Process = new Process() 
        Dim pi as ProcessStartInfo = new ProcessStartInfo() 
        pi.Arguments = " " + if(permanent = true, "/K" , "/C") + " " + command + " " + arguments 
        pi.FileName = "cmd.exe" 
        p.StartInfo = pi 
        p.Start() 
    End Sub
End Class

例如以这种方式调用：

MyUtilities.RunCommandCom("DIR", "/W", true)

编辑： 对于一行中的多个命令，键是 & | && 和 ||命令连接器

• A & B → 执行命令A，再执行命令B。
• 一个 | B → 执行命令 A，并将它的所有输出重定向到 命令 B 的输入。
• A && B → 执行命令A，运行后判断errorlevel 命令A，如果退出代码（errorlevel）为0，才执行 命令 B。
• 一个 || B → 执行命令A，判断该命令的退出码 如果不是 0，则只执行命令 B。

Answer 2

你可以试试这个来运行命令然后cmd退出

Process.Start("cmd", "/c YourCode")

你可以试试这个来运行命令并让cmd等待更多命令

Process.Start("cmd", "/k YourCode")

Answer 3

Steve 的回答启发了我，但我想我会为它添加一些闪光点。 我喜欢在编写扩展方法之前先做这些工作，所以以后调用该方法的工作就更少了。

例如，使用下面史蒂夫答案的修改版本，而不是拨打这个电话......

MyUtilities.RunCommandCom("DIR", "/W", true)

我实际上可以只输入命令并像这样从我的字符串中调用它...

直接在代码中。

Call "CD %APPDATA% & TREE".RunCMD()

或

来自一个变量。

Dim MyCommand = "CD %APPDATA% & TREE"
MyCommand.RunCMD()

或

来自文本框。

textbox.text.RunCMD(WaitForProcessComplete:=True)

---

扩展方法需要放在公共模块中，并在子模块上携带<Extension> 属性。您还需要将Imports System.Runtime.CompilerServices 添加到代码文件的顶部。

如果您需要进一步的帮助，有大量关于扩展方法的 SO 信息。

---

扩展方法

Public Module Extensions
''' <summary>
''' Extension method to run string as CMD command.
''' </summary>
''' <param name="command">[String] Command to run.</param>
''' <param name="ShowWindow">[Boolean](Default:False) Option to show CMD window.</param>
''' <param name="WaitForProcessComplete">[Boolean](Default:False) Option to wait for CMD process to complete before exiting sub.</param>
''' <param name="permanent">[Boolean](Default:False) Option to keep window visible after command has finished. Ignored if ShowWindow is False.</param>
<Extension>
Public Sub RunCMD(command As String, Optional ShowWindow As Boolean = False, Optional WaitForProcessComplete As Boolean = False, Optional permanent As Boolean = False)
    Dim p As Process = New Process()
    Dim pi As ProcessStartInfo = New ProcessStartInfo()
    pi.Arguments = " " + If(ShowWindow AndAlso permanent, "/K", "/C") + " " + command
    pi.FileName = "cmd.exe"
    pi.CreateNoWindow = Not ShowWindow
    If ShowWindow Then
        pi.WindowStyle = ProcessWindowStyle.Normal
    Else
        pi.WindowStyle = ProcessWindowStyle.Hidden
    End If
    p.StartInfo = pi
    p.Start()
    If WaitForProcessComplete Then Do Until p.HasExited : Loop
End Sub
End Module

Answer 4

Sub systemcmd(ByVal cmd As String)
    Shell("cmd /c """ & cmd & """", AppWinStyle.MinimizedFocus, True)
End Sub

Answer 5

Imports System.IO
Public Class Form1
    Public line, counter As String
    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        counter += 1
        If TextBox1.Text = "" Then
            MsgBox("Enter a DNS address to ping")
        Else
            'line = ":start" + vbNewLine
            'line += "ping " + TextBox1.Text
            'MsgBox(line)
            Dim StreamToWrite As StreamWriter
            StreamToWrite = New StreamWriter("C:\Desktop\Ping" + counter + ".bat")
            StreamToWrite.Write(":start" + vbNewLine + _
                                "Ping -t " + TextBox1.Text)
            StreamToWrite.Close()
            Dim p As New System.Diagnostics.Process()
            p.StartInfo.FileName = "C:\Desktop\Ping" + counter + ".bat"
            p.Start()
        End If
    End Sub
End Class

这个也可以