Clojurescript 异步 <?宏

Question

我一直在 swanodette 的代码中看到这个宏 <?，看起来非常有用：

在这个gist：

;; BOOM!!! we can convert async errors into exceptions
(go (try
      (let [x (<? (run-task (.-readFile fs) "foo.txt" "utf8"))]
        (.log js/console "Success" x))
      (catch js/Error e
        (.log js/console "Oops" e))))

在这篇博文中：

(go (try
      (let [tweets    (<? (get-tweets-for "swannodette"))
            first-url (<? (expand-url (first (parse-urls tweets))))
            response  (<? (http-get first-url))]
        (. js/console (log "Most recent link text:" response)))
      (catch js/Error e
        (. js/console (error "Error with the twitterverse:" e)))))

<? 只是一个宏糖，扩展成类似的东西 （抛出错误（<! [expr]））。在 core.async <! 中的目的与 ES6 的收益操作符。如果异步进程将错误写入 它的通道我们会将其转换为异常。

但我找不到它的定义。 Clojure{Script} 中是如何实现的？

Answer 1

好的，这就是我目前使用的。可能还有改进的余地。

在 Clojure 中：

(defn throw-err [e]
  (when (instance? Throwable e) (throw e))
  e)

(defmacro <? [ch]
  `(throw-err (<! ~ch)))

在 ClojureScript 中：

(defn error? [x]
  (instance? js/Error x))


(defn throw-err [e]
  (when (error? e) (throw e))
  e)

(defmacro <? [ch]
  `(throw-err (<! ~ch)))

虽然我完全不确定我的解决方案的可读性（throw-err 看起来应该会引发错误，但实际上不会。至少不是每次都这样）。